#include <WiFi.h>
#include <PubSubClient.h>
#include "DHTesp.h"

const int DHT_PIN = 15;
const int LED_PIN = 12;

DHTesp dhtSensor;

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";
const char *SubTopic1 = "ale9ufo/mqtt/led";
const char *PubTopic1 = "ale9ufo/mqtt/temp";
const char *PubTopic2 = "ale9ufo/mqtt/hum";


WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE  (50)
float temp = 0;
float hum = 0;
int value = 0;

String LEDjson = "";
bool Flash = false;  //true
//=========================================================================
void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}
//=========================================================================
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  String messageTemp;
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    messageTemp += (char)payload[i];
  }

  if (strcmp(topic, SubTopic1) == 0) {
    // If the relay is on turn it off (and vice-versa)
    Serial.println();
    Serial.println(messageTemp);  
    
    if (messageTemp == "on") {
      digitalWrite(LED_PIN, HIGH);  // Turn on the LED
      //ledState = true;  //ledState = ture HIGH
      //設定 各個 旗號
      LEDjson ="ON";
      Flash = false;
      Serial.print("LED =");
      Serial.println(LEDjson);
    }

    if (messageTemp == "off" ) {
      digitalWrite(LED_PIN , LOW); // Turn off the LED
      //ledState = false; //ledState = false LOW
      LEDjson ="OFF";
      Flash = false;
      Serial.print("LED =");
      Serial.println(LEDjson);
    }
  
    if (messageTemp == "flash" ) {
      digitalWrite(LED_PIN, HIGH); // Turn off the LED
      Flash = true;
      LEDjson ="FLASH";
      Serial.print("LED =");
      Serial.println(LEDjson);      
    }
  }
}
//=========================================================================
void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      // Once connected, publish an announcement...
      client.publish("ale9ufo/mqtt", "Indobot");
      // ... and resubscribe
      client.subscribe(SubTopic1);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}
//=========================================================================
void setup() {
  pinMode(LED_PIN, OUTPUT);     // Initialize the BUILTIN_LED pin as an output

  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  client.subscribe(SubTopic1);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
}
//=========================================================================
void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  
  if (Flash){
    digitalWrite(LED_PIN, !digitalRead(LED_PIN));
    delay(250);
  } //(Flash)

  unsigned long now = millis();
  if (now - lastMsg > 5000) {
    lastMsg = now;
    TempAndHumidity  data = dhtSensor.getTempAndHumidity();

    String temp = String(data.temperature, 2);
    Serial.print("Temperature: ");
    Serial.println(temp);
    client.publish(PubTopic1, temp.c_str());
    
    String hum = String(data.humidity, 1);
    Serial.print("Humidity: ");
    Serial.println(hum);
    client.publish(PubTopic2, hum.c_str());
  }
}