#include <WiFi.h>
#include <PubSubClient.h>

// WiFi Settings
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT Settings
const char* mqtt_server = "broker.emqx.io";
const int mqtt_port = 1883;
const char* mqtt_topic = "LBCMH/1";
const char* mqtt_username = "hello";
const char* mqtt_password = "0000";

WiFiClient espClient;
PubSubClient client(espClient);

// Relay pin
const int relayPin = 5;  // pakai GPIO5

String macAddress;
bool firstConnection = true;

void setup_wifi() {
  delay(10);
  Serial.begin(115200);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  // Get MAC Address
  byte mac[6];
  WiFi.macAddress(mac);
  char macStr[18];
  snprintf(macStr, sizeof(macStr), "%02X:%02X:%02X:%02X:%02X:%02X",
           mac[0], mac[1], mac[2], mac[3], mac[4], mac[5]);
  macAddress = String(macStr);
  Serial.print("MAC Address: ");
  Serial.println(macAddress);
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message;
  for (unsigned int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  Serial.println(message);

  // Control relay based on MQTT message
  if (message == "relay=on") {
    digitalWrite(relayPin, LOW);  // Relay ON (LEDs ON)
    Serial.println("Relay turned ON");
  }
  else if (message == "relay=off") {
    digitalWrite(relayPin, HIGH); // Relay OFF (LEDs OFF)
    Serial.println("Relay turned OFF");
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");

    String clientId = "ESP32-" + macAddress;

    if (client.connect(clientId.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("connected");
      client.subscribe(mqtt_topic, 1); // Subscribe ke topic
      if (firstConnection) {
        client.publish(mqtt_topic, "ESP32 connected");
        firstConnection = false;
      }
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(relayPin, OUTPUT);
  digitalWrite(relayPin, HIGH); // Default OFF

  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
  client.setBufferSize(256);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}