#include <WiFi.h>
#include <MQTT.h>
#include "DHTesp.h"
#include <ESP32Servo.h>
#include <NusabotSimpleTimer.h>

const char* ssid = "Wokwi-GUEST";
const char* pass = "";

const int pinRed = 2;
const int pinGreen = 4;
const int pinBlue = 16;
const int pinLed = 13;
const int pinServo = 18;
const int pinPot = 33;
const int pinDht = 25;

WiFiClient  net;
MQTTClient client;
Servo servo;
NusabotSimpleTimer timer;
DHTesp dhtSensor;

int pot, oldPot = 0;
String serial_number = "001";

void setup() {
  pinMode(pinRed, OUTPUT);
  pinMode(pinGreen, OUTPUT);
  pinMode(pinBlue, OUTPUT);
  pinMode(pinLed, OUTPUT);
  pinMode(pinPot, INPUT);

  dhtSensor.setup(pinDht, DHTesp::DHT22);

  // Serial.begin(9600);
  servo.attach(pinServo, 500, 2400);

  WiFi.begin(ssid, pass);
  client.begin("malascoding.cloud.shiftr.io", net);

  client.onMessage(subscribe);
  timer.setInterval(1000, publish);
  timer.setInterval(2000, publishdht);

  connect();
}

void loop() {
  client.loop();
  timer.run();
    if(!client.connected()){
      connect();
    }
}

void subscribe(String &topic, String &data){
  if( topic == "kelasiot/"+ serial_number +"/led"){
    if(data == "nyala"){
      digitalWrite(pinLed, 1);
    } else if(data == "mati"){
      digitalWrite(pinLed, 0);
    }
  }

  if(topic == "kelasiot/"+ serial_number +"/servo"){
    int posServo = data.toInt();
    servo.write(posServo);
  }
}

void publish(){
  pot = analogRead(pinPot);
 
  if(pot != oldPot){
    client.publish("kelasiot/"+ serial_number +"/potensiometer", String(pot), false, 1);
    oldPot = pot;
  }

}

void publishdht(){

  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  client.publish("kelasiot/"+ serial_number +"/suhu", String(data.temperature, 2) + "°C", true, 1);
  client.publish("kelasiot/"+ serial_number +"/kelembapan", String(data.humidity, 1) + "%", true, 1);

}

void rgb (bool red, bool green, bool blue){
  digitalWrite(pinRed, red);
  digitalWrite(pinGreen, green);
  digitalWrite(pinBlue, blue);
}

void connect (){

  rgb(1,0,0); //Jika merah menyala menandakan menghbungkan ke wfi

  while(WiFi.status() != WL_CONNECTED){
    delay(500);
  }

  rgb(0,1,0); // Jika Hijau maka wifi terhubung
  client.setWill("kelasiot/status/001", "offline", true, 1);
  while(!client.connect("clientid-unik", "malascoding", "FUMB94rzojkuSEUI")){
    delay(500);
  }

  rgb(0,0,1); // Jika biru maka terhbung ke broker MQTT
  client.publish("kelasiot/status/001", "online", true, 1);
  client.subscribe("kelasiot/#", 1); // subscribe ke qos 1 jika berhasil terhbung
}


// FUMB94rzojkuSEUI