#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqttServer = "broker.hivemq.com";
const int mqttPort = 1883; 
const char* mqttTopic = "wokwi/jkan/light/single";
char* clientId = "clientId-rgb-led";

WiFiClient espClient;
PubSubClient client(espClient);

#define RED_PIN 5
#define GREEN_PIN 14
#define BLUE_PIN 13
#define COMMON_PIN 26

void setup() {
  Serial.begin(115200);

  pinMode(RED_PIN, OUTPUT);
  pinMode(GREEN_PIN, OUTPUT);
  pinMode(BLUE_PIN, OUTPUT);
  pinMode(COMMON_PIN, OUTPUT);
  digitalWrite(COMMON_PIN, LOW);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected to WiFi!");

  client.setServer(mqttServer, mqttPort);
  client.setCallback(callback);
  reconnectMQTTClient();
}

void reconnectMQTTClient() {
  while (!client.connected()) {
    Serial.println("Connecting to MQTT...");
    if (client.connect(clientId)) {
      Serial.println("Connected!");
      client.subscribe(mqttTopic);
    } else {
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  String msgString;
  for (int i = 0; i < length; i++) {
    msgString += (char)message[i];
  }

  DynamicJsonDocument doc(128);
  DeserializationError error = deserializeJson(doc, msgString);
  if (error) return;

  uint8_t red = doc["r"].as<uint8_t>();
  uint8_t green = doc["g"].as<uint8_t>();
  uint8_t blue = doc["b"].as<uint8_t>();
  uint8_t brightness = doc["brightness"].as<uint8_t>();

  red = map(brightness, 0, 100, 0, red);
  green = map(brightness, 0, 100, 0, green);
  blue = map(brightness, 0, 100, 0, blue);

  analogWrite(RED_PIN, red);
  analogWrite(GREEN_PIN, green);
  analogWrite(BLUE_PIN, blue);
}

void loop() {
  if (!client.connected()) reconnectMQTTClient();
  client.loop();
}