#include <DHT.h>
#include <WiFi.h>

#define DHTPIN 14          // GPIO14 sur ESP32
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// Informations Wi-Fi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Paramètres ThingSpeak
const char* server = "api.thingspeak.com";
const int myChannelNumber =  2958786; // ThingSpeak channel number
const String apiKey = "RWZDDA2RPABB0V0O";  // Clé API écriture

WiFiClient client;

void setup() {
  Serial.begin(115200);
  delay(2000);
  dht.begin();

  connectToWiFi();
}

void loop() {
  // Vérifie et reconnecte si Wi-Fi déconnecté
  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("Wi-Fi déconnecté. Reconnexion...");
    connectToWiFi();
  }

  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();

  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Échec de lecture du capteur DHT !");
    delay(2000);
    return;
  }

  Serial.print("Température : ");
  Serial.print(temperature);
  Serial.print(" °C\tHumidité : ");
  Serial.print(humidity);
  Serial.println(" %");

  if (client.connect(server, 80)) {
    String url = "/update?api_key=" + apiKey +
                 "&field1=" + String(temperature) +
                 "&field2=" + String(humidity);

    client.print(String("GET ") + url + " HTTP/1.1\r\n" +
                 "Host: " + server + "\r\n" +
                 "Connection: close\r\n\r\n");

    Serial.println("Données envoyées à ThingSpeak !");
  } else {
    Serial.println("Connexion à ThingSpeak échouée.");
  }

  client.stop();
  delay(15000); // Minimum 15 sec entre deux envois pour ThingSpeak
}

// Fonction pour se connecter au Wi-Fi
void connectToWiFi() {
  WiFi.begin(ssid, password);
  Serial.print("Connexion à ");
  Serial.println(ssid);

  int retry = 0;
  while (WiFi.status() != WL_CONNECTED && retry < 20) {
    delay(500);
    Serial.print(".");
    retry++;
  }

  if (WiFi.status() == WL_CONNECTED) {
    Serial.println("\nWi-Fi connecté !");
    Serial.print("Adresse IP : ");
    Serial.println(WiFi.localIP());
  } else {
    Serial.println("\nÉchec de connexion au Wi-Fi.");
  }
}