#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// WiFi ma'lumotlari
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT broker manzili
const char* mqtt_server = "broker.hivemq.com";

// DHT22 sensor sozlamalari
#define DHTPIN 14        // DHT signali ulangan pin (GPIO15)
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// WiFi va MQTT uchun obyektlar
WiFiClient espClient;
PubSubClient client(espClient);

// Har 5 soniyada yuborish uchun taymer
unsigned long lastMsg = 0;
const long interval = 5000;

void setup_wifi() {
  Serial.print("WiFiga ulanmoqda...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFiga ulandi!");
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("MQTT brokerga ulanmoqda...");
    String clientId = "ESP32Client-" + String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("MQTT brokerga ulandi!");
    } else {
      Serial.print("Xatolik. Kod: ");
      Serial.println(client.state());
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  dht.begin();
  setup_wifi();
  client.setServer(mqtt_server, 1883);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > interval) {
    lastMsg = now;

    float h = dht.readHumidity();
    float t = dht.readTemperature();

    if (isnan(h) || isnan(t)) {
      Serial.println("Sensor xatolik berdi!");
      return;
    }

    char msg[50];
    snprintf(msg, 50, "Yuborildi -> Namlik: %.1f%%, Harorat: %.1fC", h, t);

    client.publish("esp32/dht", msg);
    Serial.println(msg);
  }
}