#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

// OLED 設定
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

// DHT22 設定
#define DHTPIN 2
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// 警示裝置
#define LEDPIN 7
#define BUZZERPIN 8

void setup() {
  Serial.begin(9600);
  dht.begin();

  // OLED 初始化
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println("OLED 初始化失敗");
    while (1);
  }

  // 警示裝置初始化
  pinMode(LEDPIN, OUTPUT);
  pinMode(BUZZERPIN, OUTPUT);
  digitalWrite(LEDPIN, LOW);
  digitalWrite(BUZZERPIN, LOW);

  // 顯示啟動畫面
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.println("DHT22 Sensor Ready!");
  display.display();
  delay(2000);
}

void loop() {
  delay(2000);  // 每2秒讀一次感測值

  float h = dht.readHumidity();
  float t = dht.readTemperature();

  if (isnan(h) || isnan(t)) {
    Serial.println("讀取失敗");
    display.clearDisplay();
    display.setCursor(0, 0);
    display.println("DHT22 Error!");
    display.display();
    return;
  }

  Serial.print("溫度: ");
  Serial.print(t);
  Serial.print(" °C 濕度: ");
  Serial.print(h);
  Serial.println(" %");

  // 顯示到 OLED 上
  display.clearDisplay();
  display.setTextSize(1);
  display.setCursor(0, 0);
  display.print("Temp: ");
  display.print(t);
  display.println(" C");

  display.print("Humi: ");
  display.print(h);
  display.println(" %");

  // 警示條件
  if (t > 30.0 || h > 70.0) 
  {
    digitalWrite(LEDPIN, HIGH);
    digitalWrite(BUZZERPIN, HIGH);
    display.println("!! WARNING !!");
  } else {
    digitalWrite(LEDPIN, LOW);
    digitalWrite(BUZZERPIN, LOW);
  }

  display.display();
}