// طيب هو الكود شغال بنظام event 
// you send event to rotate the servo or turn on and off the red led 
// and upload data with mqtt protocol
// ملحوظه i used l2c cuz it take less pins than lcd (more easier to use) :)

#include <Adafruit_Sensor.h>
#include <DHT_U.h>
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>
#include <LiquidCrystal_I2C.h>

#define DHTPIN 12
#define LED 26
#define SERVO_PIN 2
#define TRIG_PIN 13
#define ECHO_PIN 14

#define DHTTYPE    DHT22
DHT_Unified dht(DHTPIN, DHTTYPE);
uint32_t delayMS;

Servo servo;

LiquidCrystal_I2C lcd(0x27, 16, 2);

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.hivemq.com";
const char* clientID = "ujaisldaaasdfgh;laslksdja1";
const char* topic = "Tempdata";
const char* ultrasonicTopic = "Distancedata";

unsigned long previousMillis = 0;
const long interval = 1000;
unsigned long ultrasonicPreviousMillis = 0;
const long ultrasonicInterval = 500;
unsigned long lcdUpdatePreviousMillis = 0;
const long lcdUpdateInterval = 1000;
String msgStr = "";
float temp, hum;
float distance = 0;

WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect(clientID)) {
      Serial.println("MQTT connected");
      client.subscribe("lights");
      client.subscribe("servo");
      client.subscribe("lcd/message");
      client.subscribe("ultrasonic/trigger");
      Serial.println("Topic Subscribed");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void updateLCDWithDistance(float dist) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Distance: ");
  lcd.print(dist);
  lcd.print("cm");
  
  lcd.setCursor(0, 1);
  if (dist < 20) {
    lcd.print("Status: CLOSE");
  } else if (dist < 100) {
    lcd.print("Status: MEDIUM");
  } else {
    lcd.print("Status: FAR");
  }
}

float readUltrasonicDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  
  long duration = pulseIn(ECHO_PIN, HIGH, 30000);
  
  float distance_cm = duration * 0.034 / 2;
  
  if (distance_cm > 400 || distance_cm <= 0) {
    Serial.println("Out of range or error reading ultrasonic sensor");
    return -1;
  }
  
  return distance_cm;
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived in topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String data = "";
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    data += (char)payload[i];
  }
  Serial.println();
  Serial.print("Message size: ");
  Serial.println(length);
  Serial.println();
  Serial.println("-----------------------");
  Serial.println(data);

  if (String(topic) == "lights") {
    if (data == "ON") {
      Serial.println("LED");
      digitalWrite(LED, HIGH);
    } else {
      digitalWrite(LED, LOW);
    }
  } else if (String(topic) == "servo") {
    int degree = data.toInt();
    Serial.print("Moving servo to degree: ");
    Serial.println(degree);
    servo.write(degree);
  } else if (String(topic) == "lcd/message") {
    lcd.clear();
    String firstLine = data;
    if (data.length() > 16) {
      firstLine = data.substring(0, 16);
      lcd.setCursor(0, 0);
      lcd.print(firstLine);
      if (data.length() > 16) {
        String secondLine = data.substring(16, 32);
        lcd.setCursor(0, 1);
        lcd.print(secondLine);
      }
    } else {
      lcd.setCursor(0, 0);
      lcd.print(data);
    }
  } else if (String(topic) == "ultrasonic/trigger") {
    distance = readUltrasonicDistance();
    if (distance > 0) {
      updateLCDWithDistance(distance);
      String distanceMsg = String(distance);
      byte arrSize = distanceMsg.length() + 1;
      char msg[arrSize];
      distanceMsg.toCharArray(msg, arrSize);
      client.publish(ultrasonicTopic, msg);
      Serial.print("Manual ultrasonic reading: ");
      Serial.println(distance);
      int servoPos = map(distance, 0, 100, 0, 180);
      servoPos = constrain(servoPos, 0, 180);
      servo.write(servoPos);
    }
  }
}

void setup() {
  Serial.begin(115200);
  
  lcd.init();
  lcd.backlight();
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("IoT Distance");
  lcd.setCursor(0, 1);
  lcd.print("Monitor System");
  
  dht.begin();
  
  sensor_t sensor;
  dht.temperature().getSensor(&sensor);
  dht.humidity().getSensor(&sensor);
  
  pinMode(LED, OUTPUT);
  digitalWrite(LED, LOW);

  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);

  servo.attach(SERVO_PIN, 500, 2400);
  servo.write(0);
  
  setup_wifi();
  client.setServer(mqttServer, 1883);
  client.setCallback(callback);
  
  delay(2000);
  lcd.clear();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  
  unsigned long currentMillis = millis();
  
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;
    
    sensors_event_t event;
    dht.temperature().getEvent(&event);
    if (isnan(event.temperature)) {
      Serial.println(F("Error reading temperature!"));
    } else {
      Serial.print(F("Temperature: "));
      temp = event.temperature;
      Serial.print(temp);
      Serial.println(F("°C"));
    }
    
    dht.humidity().getEvent(&event);
    if (isnan(event.relative_humidity)) {
      Serial.println(F("Error reading humidity!"));
    } else {
      Serial.print(F("Humidity: "));
      hum = event.relative_humidity;
      Serial.print(hum);
      Serial.println(F("%"));
    }
    
    msgStr = String(temp) + "," + String(hum) + "," + String(distance);
    byte arrSize = msgStr.length() + 1;
    char msg[arrSize];
    Serial.print("PUBLISH DATA: ");
    Serial.println(msgStr);
    msgStr.toCharArray(msg, arrSize);
    client.publish(topic, msg);
    msgStr = "";
  }
  
  if (currentMillis - ultrasonicPreviousMillis >= ultrasonicInterval) {
    ultrasonicPreviousMillis = currentMillis;
    
    distance = readUltrasonicDistance();
    
    if (distance > 0) {
      Serial.print("Distance: ");
      Serial.print(distance);
      Serial.println(" cm");
      
      String distanceMsg = String(distance);
      byte arrSize = distanceMsg.length() + 1;
      char msg[arrSize];
      distanceMsg.toCharArray(msg, arrSize);
      client.publish(ultrasonicTopic, msg);
    }
  }
  
  if (currentMillis - lcdUpdatePreviousMillis >= lcdUpdateInterval) {
    lcdUpdatePreviousMillis = currentMillis;
    
    if (distance > 0) {
      updateLCDWithDistance(distance);
    }
  }
}