#include <WiFi.h>
#include <HTTPClient.h>

#define TRIG_PIN 13
#define ECHO_PIN 27

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* googleScriptURL = "https://script.google.com/macros/s/AKfycbx-GDXtZqyCfoGN7x_BD5Hi1CugCN_OprTojbYA7mNhR5LqVSKY4j7AxO88S-P9BhvCYg/exec";

void setup() {
  Serial.begin(115200);

  WiFi.begin(ssid, password);
  Serial.print("Menghubungkan ke WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi terhubung");

  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
}

void loop() {
  // Memicu sensor ultrasonik
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);

  long duration = pulseIn(ECHO_PIN, HIGH);
  float distance = (duration * 0.0343) / 2;

  Serial.print("Jarak: ");
  Serial.print(distance);
  Serial.println(" cm");

  if (WiFi.status() == WL_CONNECTED) {
    HTTPClient http;
    http.begin(googleScriptURL);
    http.addHeader("Content-Type", "application/json");

    String postData = "{\"distance\": " + String(distance) + "}";

    int httpResponseCode = http.POST(postData);

    if (httpResponseCode > 0) {
      String response = http.getString();
      Serial.println("Respon server: " + response);
    } else {
      Serial.print("Gagal kirim data, kode error: ");
      Serial.println(httpResponseCode);
    }

    http.end();
  } else {
    Serial.println("WiFi terputus");
  }

  delay(15000);  // tunggu 15 detik
}