#include "DHT.h"
#include <WiFi.h>
#include "ThingSpeak.h"

#define DHTPIN 15
#define DHTTYPE DHT22

#define DATA_PIN  23  // DS
#define CLOCK_PIN 18  // SHCP
#define LATCH_PIN 5   // STCP

const char* WIFI_NAME = "Wokwi-GUEST";
const char* WIFI_PASSWORD = "";
const int myChannelNumber = 2975058;
const char* myApiKey = "4TWONDDMHHYQ71C3";
const char* server = "api.thingspeak.com";

WiFiClient client;
DHT dht(DHTPIN, DHTTYPE);

byte digitToSegment[] = {
  0b11000000, // 0
  0b11111001, // 1
  0b10100100, // 2
  0b10110000, // 3
  0b10011001, // 4
  0b10010010, // 5
  0b10000010, // 6
  0b11111000, // 7
  0b10000000, // 8
  0b10010000, // 9
  0b11111111  // blank (all segments off)
};

void setup() {
  Serial.begin(115200);
  Serial.println(F("DHT22 + LED Display Example"));

  pinMode(DATA_PIN, OUTPUT);
  pinMode(CLOCK_PIN, OUTPUT);
  pinMode(LATCH_PIN, OUTPUT);

  WiFi.begin(WIFI_NAME, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Wifi not connected");
  }
  Serial.println("Wifi connected !");
  Serial.println("Local IP: " + String(WiFi.localIP()));
  WiFi.mode(WIFI_STA);

  ThingSpeak.begin(client);
  dht.begin();
}

void displayTemperature(float temp) {
  int intTemp = (int)(temp * 10); // VD: 25.3°C -> 253
  byte digits[4];

  digits[3] = intTemp % 10; intTemp /= 10;
  digits[2] = intTemp % 10; intTemp /= 10;
  digits[1] = intTemp % 10; intTemp /= 10;
  digits[0] = (intTemp > 0) ? intTemp % 10 : 10;

  for (int i = 0; i < 4; i++) {
    digitalWrite(LATCH_PIN, LOW);

    byte seg = digitToSegment[digits[i]];
    if (i == 2) seg &= 0b01111111; // chấm thập phân

    shiftOut(DATA_PIN, CLOCK_PIN, MSBFIRST, seg);
    shiftOut(DATA_PIN, CLOCK_PIN, MSBFIRST, 1 << i);

    digitalWrite(LATCH_PIN, HIGH);
    delay(5);
  }
}

void loop() {
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (isnan(temperature) || isnan(humidity)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    digitalWrite(LATCH_PIN, LOW);
    shiftOut(DATA_PIN, CLOCK_PIN, MSBFIRST, 0xFF);
    shiftOut(DATA_PIN, CLOCK_PIN, MSBFIRST, 0x00);
    digitalWrite(LATCH_PIN, HIGH);
    delay(5000);
    return;
  }

  Serial.print(F("Humidity: "));
  Serial.print(humidity);
  Serial.print(F("%  Temperature: "));
  Serial.print(temperature);
  Serial.println(F("°C "));

  ThingSpeak.setField(1, temperature);
  ThingSpeak.setField(2, humidity);
  int x = ThingSpeak.writeFields(myChannelNumber, myApiKey);

  if (x == 200) {
    Serial.println("Data pushed successfully");
  } else {
    Serial.println("Push error: " + String(x));
  }

  // Hiển thị nhiệt độ trong 5 giây
  unsigned long start = millis();
  while (millis() - start < 5000) {
    displayTemperature(temperature);
  }

  Serial.println("----");

  // Đảm bảo đủ thời gian giữa các lần gửi dữ liệu
  delay(16000);
}