#include <DHT.h>
#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>

// Wi-Fi Credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT Broker Settings
const char* mqtt_server = "mqtt.eclipseprojects.io"; // Example public broker
const char* mqtt_topic = "esp32/test/topic04"; // Topic to publish to

// DHT Sensor Settings
#define DHTPIN 4        
#define DHTTYPE DHT11  
DHT dht(DHTPIN, DHTTYPE);

// TMP36 Settings
const int analogPin = 34; 
const float BETA = 3950.0;

WiFiClient espClient;
PubSubClient client(espClient);

// Function to connect to Wi-Fi
void connectWiFi() {
  Serial.println("Connecting to WiFi...");
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("WiFi Connected");
}

// Function to connect to the MQTT broker
void connectMQTT() {
  while (!client.connected()) {
    Serial.println("Attempting MQTT connection...");
    // Create a unique client ID
    String clientId = "ESP32Client-" + String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected to MQTT broker");
    } else {
      Serial.print("Failed to connect, state: ");
      Serial.println(client.state());
      delay(5000); // Retry after 5 seconds
    }
  }
}

// MQTT Callback to handle incoming messages
void callback(char* topic, byte* payload, unsigned int length) {
  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  Serial.print("Received message: ");
  Serial.println(message);
}

void setup() {
  Serial.begin(115200); // Initialize Serial Monitor
  
  // Initialize sensors
  pinMode(analogPin, INPUT);
  dht.begin();
  
  // Connect to WiFi and MQTT
  connectWiFi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  connectMQTT();
}

void loop() {
  if (!client.connected()) {
    connectMQTT(); // Reconnect if the connection is lost
  }
  client.loop(); // Keep the connection alive
  
  // Read sensor data
  int analogValue = analogRead(analogPin);
  float tmp36Temp = 1 / (log(1 / (4095.0 / analogValue - 1)) / BETA + 1.0 / 298.15) - 273.15;
  float dhtTemp = dht.readTemperature(); 
  float humidity = dht.readHumidity();

  // Create JSON document
  StaticJsonDocument<200> doc;
  doc["sensor"] = "ESP32";
  doc["dht11_temp"] = dhtTemp;
  doc["dht11_humidity"] = humidity;
  doc["tmp36_temp"] = tmp36Temp;
  doc["timestamp"] = millis();

  // Serialize JSON to string
  char jsonBuffer[200];
  serializeJson(doc, jsonBuffer);

  // Print to serial for debugging
  Serial.println("Sending JSON:");
  Serial.println(jsonBuffer);

  // Publish JSON to MQTT
  client.publish(mqtt_topic, jsonBuffer);

  delay(5000); // Wait 5 seconds between readings
}