#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Wire.h>

// OLED Display settings
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Ultrasonic Sensor pins
const int trigPin = 9;
const int echoPin = 10;

// LED and Buzzer pins
const int ledPin = 6;
const int buzzerPin = 7;

void setup() {
  Serial.begin(9600);

  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(ledPin, OUTPUT);
  pinMode(buzzerPin, OUTPUT);

  // Initialize OLED
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("OLED display not found!"));
    while (true); // Stop here
  }

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  // Trigger pulse
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  // Read echo time
  long duration = pulseIn(echoPin, HIGH);

  // Convert to distance
  float distanceCM = duration * 0.034 / 2;
  float distanceInches = distanceCM / 2.54;

  // Display on OLED
  display.clearDisplay();
  display.setCursor(0, 10);
  display.setTextSize(2);
  display.print("CM: ");
  display.println(distanceCM, 1);

  display.setCursor(0, 35);
  display.setTextSize(2);
  display.print("In: ");
  display.println(distanceInches, 1);

  display.display();

  // Alert section
  if (distanceCM <= 10) {
    digitalWrite(ledPin, HIGH);

    // Beeping like bomb
    for (int i = 0; i < 3; i++) {
      tone(buzzerPin, 1000); // Beep sound
      delay(100);
      noTone(buzzerPin);
      delay(100);
    }
  } else {
    digitalWrite(ledPin, LOW);
    noTone(buzzerPin);
  }

  delay(500); // Refresh every 0.5 seconds
}