#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "test.mosquitto.org";
const int mqtt_port = 1883;
const char* mqtt_topic = "saiam indianos";

#define ledPin 33  // Pino do LED

WiFiClient espClient;
PubSubClient client(espClient);

void callback(char* topic, byte* message, unsigned int length) {
  String msg;
  for (unsigned int i = 0; i < length; i++) {
    msg += (char)message[i];  // Constrói a mensagem recebida
  }

  Serial.print("Mensagem recebida: ");
  Serial.println(msg);

  // Controla o LED com base na mensagem
  if (msg == "true") {
    digitalWrite(ledPin, HIGH); // Liga o LED
    Serial.println("LED LIGADO");
  } else if (msg == "false") {
    digitalWrite(ledPin, LOW); // Desliga o LED
    Serial.println("LED DESLIGADO");
  }
}

void setup_wifi() {
  delay(100);
  Serial.println("Conectando ao Wi-Fi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("Wi-Fi conectado!");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Tentando conexão MQTT...");
    String clientId = "ESP32ClientLED-" + String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Conectado!");
      client.subscribe(mqtt_topic); // Inscreve no tópico
    } else {
      Serial.print("Falha, rc=");
      Serial.print(client.state());
      Serial.println(" tentando novamente em 5 segundos");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(ledPin, OUTPUT);      // Configura pino do LED como saída
  digitalWrite(ledPin, LOW);    // Garante LED desligado inicialmente
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop(); // Mantém o cliente MQTT operando
}