// Đây à code Wowki 
#include <WiFi.h>
#include <PubSubClient.h>
#include <LiquidCrystal_I2C.h>

// Cấu hình WiFi và MQTT
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* MQTTServer = "broker.emqx.io";
const char* MQTT_TOPIC = "Face";
//https://www.guidgen.com/
const char* MQTT_ID = "7419cd6c-a89b-40c5-be65-52dd12abf6d9";

// Khởi tạo đối tượng
WiFiClient espClient;
PubSubClient client(espClient);
LiquidCrystal_I2C lcd(0x27, 20, 4); // LCD 20x4

// Định nghĩa chân LED
const int LED_PIN = 2;

void setup() {
  Serial.begin(115200);
  
  // Khởi tạo LCD
  lcd.init();
  lcd.backlight();
  lcd.clear();
  
  // Khởi tạo LED
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);
  
  // Kết nối WiFi
  setupWiFi();
  
  // Cấu hình MQTT
  client.setServer(MQTTServer, 1883);
  client.setCallback(callback);
}

void setupWiFi() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnectMQTT() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID)) {
      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_TOPIC);
      Serial.print(" connected");
      client.subscribe(MQTT_TOPIC);
      Serial.println("");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  
  lcd.clear();
  
  if (message == "correct") {
    // Hiển thị trạng thái mở cửa
    lcd.setCursor(0, 2);
    lcd.print("Access Granted");
    lcd.setCursor(0, 3);
    lcd.print("Door Opening");
    
    // Bật LED
    digitalWrite(LED_PIN, HIGH);
  } else if (message == "incorrect") {
    // Hiển thị trạng thái từ chối
    lcd.setCursor(0, 2);
    lcd.print("Access Denied");
    lcd.setCursor(0, 3);
    lcd.print("Door Locked");
    
    // Tắt LED
    digitalWrite(LED_PIN, LOW);
  }

  
  delay(3000);
}

void loop() {
  // Kiểm tra kết nối WiFi
  if (WiFi.status() != WL_CONNECTED) {
    lcd.setCursor(0, 0);
    lcd.print("WIFI Not Connected");
    setupWiFi();
  } else {
    lcd.setCursor(0, 0);
    lcd.print("WIFI Connected    ");
  }

  // Kiểm tra kết nối MQTT
  if (!client.connected()) {
    lcd.setCursor(0, 1);
    lcd.print("MQTT Not Connected");
    reconnectMQTT();
  } else {
    lcd.setCursor(0, 1);
    lcd.print("MQTT Connected    ");
  }

  // Xử lý các message MQTT
  client.loop();
}