#define BLYNK_TEMPLATE_ID "TMPL6XSQbVWML"
#define BLYNK_TEMPLATE_NAME "DHT22"
#define BLYNK_AUTH_TOKEN "VyTnbYmJIIabnN33kGSuaMqxqj1qN571"

#define BLYNK_PRINT Serial
#include <WiFi.h>
#include <BlynkSimpleEsp32.h>

#include <DHT.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// OLED config
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET     -1  // Reset pin # (or -1 if sharing Arduino reset)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// DHT config
#define DHTPIN 2 
#define DHTTYPE DHT22  
DHT dht(DHTPIN, DHTTYPE);

// Blynk & WiFi config
char auth[] = BLYNK_AUTH_TOKEN;
char ssid[] = "Wokwi-GUEST";
char pass[] = "";

BlynkTimer timer;

void sendSensor() {
  float h = dht.readHumidity();
  float t = dht.readTemperature(); // or dht.readTemperature(true) for Fahrenheit

  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Kirim ke Blynk Virtual Pin
  Blynk.virtualWrite(V0, t);
  Blynk.virtualWrite(V1, h);

  // Tampilkan ke Serial Monitor
  Serial.print("Temperature : ");
  Serial.print(t);
  Serial.print(" °C    Humidity : ");
  Serial.print(h);
  Serial.println(" %");

  // Tampilkan ke OLED
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0,0);
  display.println("Monitoring Temperature");

  display.setTextSize(2);
  display.setCursor(0, 20);
  display.print(t);
  display.print(" C");

  display.setTextSize(2);
  display.setCursor(0, 40);
  display.print(h);
  display.print(" %");

  display.display();
}

void setup() {
  Serial.begin(115200);

  // Inisialisasi OLED
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Alamat I2C OLED biasanya 0x3C
    Serial.println(F("OLED gagal ditemukan"));
    for(;;);
  }
  display.clearDisplay();
  display.display();

  // Inisialisasi Blynk & DHT
  Blynk.begin(auth, ssid, pass);
  dht.begin();

  // Timer kirim data tiap 1 detik
  timer.setInterval(1000L, sendSensor);
}

void loop() {
  Blynk.run();
  timer.run();
}