#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.hivemq.com";
const int mqttPort = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

const int motorPin = 23;

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "clientId-" + String(random(1000));
    const char *username = "";
    const char *password = "";
    if (client.connect(clientId.c_str(),
                       username,     // username
                       password,     // password
                       "v1/sensor",  // willTopic
                       1,            // willQoS
                       true,         // willRetain
                       "offline",    // willMessage
                       true         // cleanSession
                      )) {
      Serial.print(clientId);
      Serial.println(" connected");
      Serial.println("Publish [v1/sensor]: online");
      client.publish("v1/sensor", "online");
      client.subscribe("v1/sensor/motor/control");
    }
    else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 2 seconds");
      delay(2000);      
    }
  }
}

void callback(const char* topic, byte* payload, unsigned int length) {
  String message = "";
  for (unsigned int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("]: ");
  Serial.print(message+"=> ");

  if (String(topic) == "v1/sensor/motor/control") {
    Serial.print("Motor output: ");
    if (message == "start") {
      Serial.println(message);
      digitalWrite(motorPin, HIGH);
      client.publish("v1/sensor/motor/status", "start");
    } else if (message == "stop") {
      Serial.println(message);
      digitalWrite(motorPin, LOW);
      client.publish("v1/sensor/motor/status", "stop");
    }
  }
}

void setup() {
  Serial.begin(115200);

  pinMode(motorPin, OUTPUT);
  digitalWrite(motorPin, LOW);

  Serial.print("Connecting to Wi-Fi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWi-Fi connected!");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  client.setServer(mqttServer, mqttPort);
  client.setCallback(callback);
  // client.setKeepAlive(60*5);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}