#include <Adafruit_Sensor.h>
#include <DHT_U.h>
#include <WiFi.h>
#include <PubSubClient.h>

// Define Pins
#define DHTPIN 12
#define LED 26

// DHT parameters
#define DHTTYPE DHT22
DHT_Unified dht(DHTPIN, DHTTYPE);
uint32_t delayMS;

// MQTT Credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.hivemq.com";  // You can replace with test.mosquitto.org or broker.emqx.io
const char* clientID = "";
const char* topic = "Tempdata";

// Timer variables
unsigned long previousMillis = 0;
const long interval = 1000;
String msgStr = "";
float temp, hum;

// WiFi and MQTT client setup
WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect(clientID)) {
      Serial.println("MQTT connected");
      client.subscribe("lights");
      Serial.println("Topic Subscribed");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// MQTT callback
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived in topic: ");
  Serial.println(topic);
  String data = "";
  for (int i = 0; i < length; i++) {
    data += (char)payload[i];
  }

  Serial.println("Payload: " + data);

  if (String(topic) == "lights") {
    digitalWrite(LED, (data == "ON") ? HIGH : LOW);
  }
}

void setup() {
  Serial.begin(115200);
  dht.begin();

  sensor_t sensor;
  dht.temperature().getSensor(&sensor);
  dht.humidity().getSensor(&sensor);

  pinMode(LED, OUTPUT);
  digitalWrite(LED, LOW);

  setup_wifi();
  client.setServer(mqttServer, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;

    sensors_event_t event;
    dht.temperature().getEvent(&event);
    if (!isnan(event.temperature)) {
      temp = event.temperature;
      Serial.print("Temperature: ");
      Serial.println(temp);
    }

    dht.humidity().getEvent(&event);
    if (!isnan(event.relative_humidity)) {
      hum = event.relative_humidity;
      Serial.print("Humidity: ");
      Serial.println(hum);
    }

    msgStr = String(temp) + "," + String(hum) + ",";
    char msg[msgStr.length() + 1];
    msgStr.toCharArray(msg, msgStr.length() + 1);
    client.publish(topic, msg);
    msgStr = "";
  }
}