/*
 * Exemplo de conexão do ESP32 à rede WiFi e ao broker MQTT
 * Utiliza o broker público do HiveMQ para demonstrar a estrutura básica de cliente MQTT (subscriber)
 * 
 * Autor: Paulo H. Langome Miranda
 * Curso de Férias FESA - Introdução à IoT
*/

// Inclui a biblioteca WiFi do ESP32
#include <WiFi.h>

// Inclui a biblioteca PubSubClient para comunicação MQTT
#include <PubSubClient.h>

// Dados da rede Wi-Fi (no Wokwi, usa-se Wokwi-GUEST)
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Endereço do broker MQTT (HiveMQ público neste exemplo)
const char* mqtt_server = "broker.hivemq.com";

// Cria um objeto WiFiClient para comunicação TCP
WiFiClient espClient;

// Cria um cliente MQTT usando o cliente TCP
PubSubClient client(espClient);

// Função para conectar ao Wi-Fi
void initWiFi() {
  WiFi.mode(WIFI_STA);             // Modo estação (cliente)
  WiFi.begin(ssid, password);      // Conecta à rede Wi-Fi
  Serial.print("Conectando-se ao WiFi ..");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print('.');
    delay(1000);
  }
  Serial.println("\nConectado com IP: ");
  Serial.println(WiFi.localIP());
}

// Função chamada ao receber mensagem em tópico MQTT assinado
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Mensagem recebida no tópico: ");
  Serial.println(topic);
  Serial.print("Conteúdo: ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

// Função que tenta conectar ao broker MQTT
void reconnectMQTT() {
  // Fica tentando reconectar até conseguir
  while (!client.connected()) {
    Serial.print("Tentando conexão MQTT...");
    // Define um ID único para o client (pode ser qualquer string)
    String clientId = "ESP32Client-" + String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Conectado ao broker MQTT");

      // Após conectar, pode-se assinar tópicos (subscribe)
      client.subscribe("fesa/teste");

    } else {
      Serial.print("Falha na conexão. Código: ");
      Serial.print(client.state());
      Serial.println(" Tentando novamente em 5 segundos...");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);      // Inicia a comunicação serial
  initWiFi();                // Conecta à rede Wi-Fi

  client.setServer(mqtt_server, 1883); // Define o broker MQTT e a porta
  client.setCallback(callback);       // Define função de callback para mensagens recebidas
}

void loop() {
  // Se o cliente MQTT estiver desconectado, tenta reconectar
  if (!client.connected()) {
    reconnectMQTT();
  }

  client.loop();  // Mantém o cliente MQTT ativo e verificando novas mensagens
}