#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "broker.emqx.io";
const char* topic_sensor = "ambaNitro/arfin_desca_alzachri/LDR_sensor";
const char* topic_led = "ambaNitro/arfin_desca_alzachri/aktuasi_led";

#define LDR_PIN 34
#define LED_PIN 2

WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  Serial.println("Menghubungkan ke WiFi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(2000);
    Serial.print(".");
  }
  Serial.println("WiFi terhubung!");
}

float adcToLux(int adcValue) {
  float max_adc = 4095.0;
  float max_lux = 1000.0;
  return (adcValue / max_adc) * max_lux;
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  message.trim();
  message.toLowerCase();

  if (String(topic) == topic_led) {
    if (message == "on") {
      digitalWrite(LED_PIN, HIGH);
    } else if (message == "off") {
      digitalWrite(LED_PIN, LOW);
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Menghubungkan ke MQTT...");
    String clientId = "ESP32Client-" + String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("terhubung.");
      client.subscribe(topic_led);
    } else {
      Serial.print("Gagal, rc=");
      Serial.print(client.state());
      delay(2000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  int ldrValue = analogRead(LDR_PIN);
  float lux = adcToLux(ldrValue);

  String message = "Tingkat kecerahan adalah: " + String(lux, 2) + " lux";
  client.publish(topic_sensor, message.c_str());

  Serial.println(message);
  delay(2000);
}