#pragma once

#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <DHT.h>
#include <time.h>
#include <esp_system.h>  

#define BUTTON_PIN 15    
#define LED1_PIN 19      
#define LED2_PIN 18      
#define DHTPIN 26
#define DHTTYPE DHT22
#define BUZZER_PIN 4   

const float TEMP_THRESHOLD_C = 30.0;    
const float TEMP_THRESHOLD_F = 80.0;   
const float HUMIDITY_THRESHOLD = 60.0; 

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.hivemq.com";

const char* mqtt_topic_pub = "IoT/Warehouse1/sensor";     
const char* mqtt_topic_time = "IoT/Warehouse1/time";      
const char* mqtt_topic_sub = "IoT/Warehouse1/led";       
const char* mqtt_topic_alarm = "IoT/Warehouse1/alarm";    
const char* mqtt_topic_lwt = "IoT/Warehouse1/status";     

WiFiClient espClient;
PubSubClient client(espClient);
DHT dht(DHTPIN, DHTTYPE);
LiquidCrystal_I2C lcd(0x27, 20, 4);


bool led1State = false;             
bool led2State = false;             
unsigned long lastMsg = 0;           
unsigned long lastDisplayChange = 0;
const long publishInterval = 3000;   
const long displayInterval = 3000;   
int displayState = 0;                
char msg[100];                       
bool welcomeDisplayed = false;
bool isAlarm = false; 
unsigned long alarmStartTime = 0;
const unsigned long ALARM_DURATION = 30000;  
unsigned long lastBuzzerToggle = 0;
const long buzzerInterval = 500;            

uint8_t dot[] = {0x0E, 0x0A, 0x0E, 0x00, 0x00, 0x00, 0x00, 0x00}; 

int buttonState;                     
int lastButtonState = HIGH;         
unsigned long lastDebounceTime = 0;  
unsigned long debounceDelay = 50;    
bool restartTriggered = false;       

void setup_wifi() {
  Serial.println("Connecting to WiFi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(250);
  }
  Serial.println("\nWiFi connected successfully!");
}

void setup() {
  Serial.begin(115200);
  Serial.println("Starting setup()...");

  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(LED1_PIN, OUTPUT);
  pinMode(LED2_PIN, OUTPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(LED1_PIN, LOW);
  digitalWrite(LED2_PIN, HIGH); // LED2在系统运行时保持点亮
  digitalWrite(BUZZER_PIN, LOW);
  
  lcd.init();
  lcd.backlight();
  lcd.createChar(0, dot);
  lcd.clear();
  lcd.print("Initializing...");
  delay(1000);

  dht.begin();
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  configTime(8 * 3600, 0, "pool.ntp.org");
  struct tm timeinfo;
  while (!getLocalTime(&timeinfo)) {
    Serial.println("Waiting for time sync...");
    delay(1000);
  }
  Serial.println("Time synchronized successfully");
  displayWelcome();
  lastDisplayChange = millis();
  lastMsg = 0;

  Serial.println("setup() complete, entering loop()");
}

void displayWelcome() { 
  if (!welcomeDisplayed) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Hi,Welcome!");
    lcd.setCursor(0, 1);
    lcd.print("Warehouse1,");
    lcd.setCursor(0, 2);
    lcd.print("By Group003!");
    welcomeDisplayed = true;
    delay(2000);
  }
}

void displayDateTime() {
  struct tm timeinfo;
  if (getLocalTime(&timeinfo)) {
    char dtbuf[21];
    strftime(dtbuf, sizeof(dtbuf), "%Y-%m-%d %H:%M:%S", &timeinfo);
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("DateTime:");
    lcd.setCursor(0, 1);
    lcd.print(dtbuf);
    
    unsigned long now = millis();
    if (now - lastMsg >= publishInterval) {
      lastMsg = now;
      client.publish(mqtt_topic_time, dtbuf);
    }
  }
}

void displayTempHumidity() {
  unsigned long start = millis();
  float h = dht.readHumidity();
  float c = dht.readTemperature();
  float f = dht.readTemperature(true);
  
  if (millis() - start > 1000) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Sensor Timeout!");
    return;
  }
  
  if (isnan(h) || isnan(c) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Sensor Error!");
    return;
  }

  Serial.printf("Humidity: %.1f%%  Temp: %.1f°C / %.1f°F\n", h, c, f);

  bool tempAlarm = c > TEMP_THRESHOLD_C || f > TEMP_THRESHOLD_F;
  bool humAlarm = h > HUMIDITY_THRESHOLD;
  
  if (tempAlarm || humAlarm) {
    isAlarm = true;
    alarmStartTime = millis();
    
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("ALARM!");
    lcd.setCursor(0, 1);
    if (tempAlarm) lcd.print("Temp Over!");
    else lcd.print("Humidity Over!");
    lcd.setCursor(0, 2);
    lcd.print(tempAlarm ? String(c) + "C > " + String(TEMP_THRESHOLD_C) + "C" 
                       : String(h) + "% > " + String(HUMIDITY_THRESHOLD) + "%");
    
    char alarmMsg[100];
    snprintf(alarmMsg, sizeof(alarmMsg), "Alarm: %s %.1f%s",
             tempAlarm ? "Temp" : "Humidity",
             tempAlarm ? c : h,
             tempAlarm ? "C" : "%");
    client.publish(mqtt_topic_alarm, alarmMsg);
  } else {
    isAlarm = false;
    digitalWrite(BUZZER_PIN, LOW);
    
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Humidity: "); 
    lcd.print(h, 1); 
    lcd.print("%");
    
    lcd.setCursor(0, 1);
    lcd.print("Temperature: ");
    lcd.print(c, 2); 
    lcd.write(0); 
    lcd.print("C");

    lcd.setCursor(0, 2);
    lcd.print("Temperature: ");
    lcd.print(f, 1); 
    lcd.write(0); 
    lcd.print("F");

    unsigned long now = millis();
    if (now - lastMsg >= publishInterval) {
      lastMsg = now;
      snprintf(msg, sizeof(msg), "{\"temp\": %.1f, \"hum\": %.1f}", c, h);
      client.publish(mqtt_topic_pub, msg);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) { 
  payload[length] = 0;
  String command = String((char*)payload);
  command.toUpperCase();
  Serial.print("Received MQTT command: ");
  Serial.println(command);
  
  if (command == "ON") {
    digitalWrite(LED1_PIN, HIGH);
    digitalWrite(LED2_PIN, HIGH);
    led1State = true;
    led2State = true;
    Serial.println("LEDs turned ON via MQTT");
  } else if (command == "OFF") {
    digitalWrite(LED1_PIN, LOW);
    digitalWrite(LED2_PIN, HIGH); // LED2保持点亮
    led1State = false;
    led2State = true; // 记录LED2应该保持点亮
    Serial.println("LED1 turned OFF via MQTT, LED2 stays ON");
  }
}

void controlBuzzer(bool enable) { 
  static int buzzerPattern = 0;
  unsigned long now = millis();

  if (enable) {
    if (now - lastBuzzerToggle >= buzzerInterval) {
      lastBuzzerToggle = now;
      buzzerPattern = (buzzerPattern + 1) % 4;

      switch (buzzerPattern) {
        case 0: tone(BUZZER_PIN, 1000); break;  // 1kHz
        case 1: tone(BUZZER_PIN, 1500); break;  // 1.5kHz
        case 2: tone(BUZZER_PIN, 2000); break;  // 2kHz
        case 3: noTone(BUZZER_PIN); break;      // silent
      }
    }
  } else {
    noTone(BUZZER_PIN);  // stop any tone
  }
}

void blinkAndRestart() {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Restarting...");
  
  // 闪烁LED2三次
  for (int i = 0; i < 3; i++) {
    digitalWrite(LED2_PIN, LOW);
    delay(300);
    digitalWrite(LED2_PIN, HIGH);
    delay(300);
  }
  
  client.publish(mqtt_topic_lwt, "restarting", true);
  delay(1000);
  esp_restart();  
}

void handleButton() {
  int reading = digitalRead(BUTTON_PIN);

  if (reading != lastButtonState) {
    lastDebounceTime = millis();
  }

  if ((millis() - lastDebounceTime) > debounceDelay) {

    if (reading != buttonState) {
      buttonState = reading;

      if (buttonState == LOW && !restartTriggered) {
        restartTriggered = true;
        Serial.println("Button pressed - Blink LED2 and restart");
        blinkAndRestart();
      }
    }
  }

  lastButtonState = reading;
}

void reconnect() {
  static unsigned long lastReconnectAttempt = 0;
  const long reconnectInterval = 7000;  
  
  if (millis() - lastReconnectAttempt < reconnectInterval) return;
  lastReconnectAttempt = millis();

  Serial.println("Connecting to MQTT...");
  if (client.connect("ESP32ClientDevice", mqtt_topic_lwt, 0, true, "offline")) {
    Serial.println("MQTT connected successfully");
    client.publish(mqtt_topic_lwt, "online", true);
    client.subscribe(mqtt_topic_sub);
    client.setKeepAlive(60);
    client.setSocketTimeout(30);
  } else {
    Serial.print("MQTT connection failed, status=");
    Serial.print(client.state());
    Serial.println(", will retry....");
  }
}

void loop() {
  if (!client.connected()) reconnect();
  client.loop();
  handleButton();
  unsigned long now = millis();

  if (isAlarm) {
    controlBuzzer(true);  
    
    if (now - lastBuzzerToggle >= buzzerInterval/2) {
      lastBuzzerToggle = now;
      digitalWrite(LED1_PIN, !digitalRead(LED1_PIN)); 
      // LED2保持点亮状态，不参与报警闪烁
    }
    
    if (now - alarmStartTime > ALARM_DURATION) {
      isAlarm = false;
      digitalWrite(BUZZER_PIN, LOW);
      digitalWrite(LED1_PIN, led1State);
    }
  }

  if (now - lastDisplayChange >= displayInterval && !isAlarm && !restartTriggered) {
    lastDisplayChange = now;
    displayState = (displayState + 1) % 3;
    switch (displayState) {
      case 0: displayWelcome(); break;
      case 1: displayDateTime(); break;
      case 2: displayTempHumidity(); break;
    }
  }
}