//SSD1306 OLED DISPLAY
//LIBRARY FUNCTION USED :1)Adafruit SSD1306   2)Adafruit GFX Library

#include <DHT.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// DHT Sensor Settings
#define DHTPIN 6     
#define DHTTYPE DHT22  
DHT dht(DHTPIN, DHTTYPE);

// OLED Settings
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

void setup() {
  Serial.begin(9600);
  dht.begin();

  // Initialize OLED
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { 
    Serial.println(F("SSD1306 allocation failed"));
    while (true);
  }

  display.clearDisplay();
  display.setTextSize(1);      
  display.setTextColor(SSD1306_WHITE); 
  display.setCursor(0, 0);     
  display.println("Initializing...");
  display.display();
  delay(1000);
}

void loop() {
  float temp = dht.readTemperature();    // Celsius
  float hum = dht.readHumidity();

  // Check if any reads failed
  if (isnan(temp) || isnan(hum)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Print to Serial
  Serial.print(F("Temperature: "));
  Serial.print(temp);
  Serial.print(F("°C  Humidity: "));
  Serial.print(hum);
  Serial.println(F("%"));

  // Display on OLED
  display.clearDisplay();
  display.setCursor(0, 0);
  display.setTextSize(1);
  display.print("Temp: ");
  display.print(temp);
  display.println(" C");

  display.print("Humidity: ");
  display.print(hum);
  display.println(" %");

  display.display();
  delay(1000);
}
// OLED DISPLAY PIN CONFIGURATION
//GND - GROUND PIN (ANY)
//VCC PIN - ONLY 3.3V [FIXED]
//SDA - IN A4 PIN [FIXED] (SERIAL DATA LINE)
//SCL - IN A5 PIN [FIXED] (SERIAL CLOCK LINE)