// --------------------------------------
// i2c-scanner
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
// See full version history here: https://gist.github.com/urish/917414da3477e528c8782ee05cd6f557

#include <Wire.h>
#define RST 5

void setup() {
  Wire.begin();
  pinMode(RST,OUTPUT);
  digitalWrite(RST,HIGH);
  delay(100);
  digitalWrite(RST,LOW);
  delay(300);
  digitalWrite(RST,HIGH);
  delay(100);

  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}

void loop() {
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++) {
    // The i2c-scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) {
        Serial.print("0");
      }
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) {
      Serial.print("Unknown error at address 0x");
      if (address<16) {
        Serial.print("0");
      }
      Serial.println(address,HEX);
    }
  }
  if (nDevices == 0) {
    Serial.println("No I2C devices found\n");
  } else {
    Serial.println("done\n");
  }

  delay(5000);           // wait 5 seconds for next scan
}