/*
  https://forum.arduino.cc/t/how-to-setup-array-structure-for-melody-sequences/1404240
*/


#define REST 0
#define NOTE_B0  31
#define NOTE_C1  33
#define NOTE_CS1 35
#define NOTE_D1  37
#define NOTE_DS1 39
#define NOTE_E1  41
#define NOTE_F1  44
#define NOTE_FS1 46
#define NOTE_G1  49
#define NOTE_GS1 52
#define NOTE_A1  55
#define NOTE_AS1 58
#define NOTE_B1  62
#define NOTE_C2  65
#define NOTE_CS2 69
#define NOTE_D2  73
#define NOTE_DS2 78
#define NOTE_E2  82
#define NOTE_F2  87
#define NOTE_FS2 93
#define NOTE_G2  98
#define NOTE_GS2 104
#define NOTE_A2  110
#define NOTE_AS2 117
#define NOTE_B2  123
#define NOTE_C3  131
#define NOTE_CS3 139
#define NOTE_D3  147
#define NOTE_DS3 156
#define NOTE_E3  165
#define NOTE_F3  175
#define NOTE_FS3 185
#define NOTE_G3  196
#define NOTE_GS3 208
#define NOTE_A3  220
#define NOTE_AS3 233
#define NOTE_B3  247
#define NOTE_C4  262
#define NOTE_CS4 277
#define NOTE_D4  294
#define NOTE_DS4 311
#define NOTE_E4  330
#define NOTE_F4  349
#define NOTE_FS4 370
#define NOTE_G4  392
#define NOTE_GS4 415
#define NOTE_A4  440
#define NOTE_AS4 466
#define NOTE_B4  494
#define NOTE_C5  523
#define NOTE_CS5 554
#define NOTE_D5  587
#define NOTE_DS5 622
#define NOTE_E5  659
#define NOTE_F5  698
#define NOTE_FS5 740
#define NOTE_G5  784
#define NOTE_GS5 831
#define NOTE_A5  880
#define NOTE_AS5 932
#define NOTE_B5  988
#define NOTE_C6  1047
#define NOTE_CS6 1109
#define NOTE_D6  1175
#define NOTE_DS6 1245
#define NOTE_E6  1319
#define NOTE_F6  1397
#define NOTE_FS6 1480
#define NOTE_G6  1568
#define NOTE_GS6 1661
#define NOTE_A6  1760
#define NOTE_AS6 1865
#define NOTE_B6  1976
#define NOTE_C7  2093
#define NOTE_CS7 2217
#define NOTE_D7  2349
#define NOTE_DS7 2489
#define NOTE_E7  2637
#define NOTE_F7  2794
#define NOTE_FS7 2960
#define NOTE_G7  3136
#define NOTE_GS7 3322
#define NOTE_A7  3520
#define NOTE_AS7 3729
#define NOTE_B7  3951
#define NOTE_C8  4186
#define NOTE_CS8 4435
#define NOTE_D8  4699
#define NOTE_DS8 4978

#define BUZZER_PIN 2
#define BTN_PIN 8



int startUp[] = {NOTE_C4, 4, NOTE_G4, 4, NOTE_E4, 4, NOTE_F4, 4, NOTE_F4, 4, NOTE_E4, 4};
int shutDown[] = {NOTE_E4, 4, NOTE_F4, 4, NOTE_F4, 4, NOTE_E4, 4, NOTE_G4, 4, NOTE_C4, 4};
int neverGiveUpTune[] = {NOTE_C4, 1, NOTE_D4, 1, NOTE_F4, 1, NOTE_D4, 1, NOTE_A4, 1, REST, 1, NOTE_A4, 1, NOTE_G4, 4, REST, 2, NOTE_C4, 1, NOTE_D4, 1, NOTE_F4, 1, NOTE_D4, 1, NOTE_G4, 1, REST, 1, NOTE_G4, 4, NOTE_G4, 4, NOTE_F4, 2}; 



//vars for playMelody
byte currTune = 0;
int currNote = 0;
bool notePlaying = false;
unsigned long noteStart;
unsigned long noteDuration;
// now
unsigned long now;
//led blinking vars
unsigned long blinkStart;
unsigned long blinkDuration = 1000;
//button debouncing
unsigned long btnStart;
unsigned long btnWait = 50;
byte btnState = 1;


//non-blocking melody player..
void playMelody(int tune[], int len) {
  if (now - noteStart >= noteDuration) {
    if (notePlaying) {
      notePlaying = false;
      //pause between notes..
      noteDuration = noteDuration * 1.3;
      noTone(BUZZER_PIN);
      noteStart = now;
      currNote += 2;
      if (currNote > len - 1) currNote = 0;
    } else {
      notePlaying = true;
      noteDuration = 1000 / tune[currNote + 1];
      tone(BUZZER_PIN, tune[currNote]);
      noteStart = now;
    }
  }
}

void setup() {
  Serial.begin(115200);
  Serial.println("Ready..");
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, HIGH);
  pinMode(BUZZER_PIN, OUTPUT);
  pinMode(BTN_PIN, INPUT_PULLUP);


}

void loop() {

  now = millis();

  //blink led once per second..
  if (now - blinkStart >= blinkDuration) {
    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    blinkStart = now;
  }


  if (now - btnStart >= btnWait) {
    byte b  = !digitalRead(BTN_PIN);
    if (b != btnState) {
      btnState = b;
      btnStart = now;
      if (btnState == HIGH) {
        currTune++;
        if (currTune > 2) currTune = 0;
        //reset for next tune..
        currNote = 0;
        notePlaying = false;
        Serial.print("Playing tune:"); Serial.println(currTune);
      }
    }
  }

  switch (currTune) {
    case 0:
      playMelody(startUp, sizeof(startUp) / sizeof(startUp[0]));
      break;
    case 1:
      playMelody(shutDown, sizeof(shutDown) / sizeof(shutDown[0]));
      break;
    case 2:
      playMelody(neverGiveUpTune, sizeof(neverGiveUpTune) / sizeof(neverGiveUpTune[0]));
      break;
  }


}