#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

#define DHTPIN 32        // D9 on XIAO ESP32-S3 = GPIO9
#define DHTTYPE DHT22   // DHT22 sensor

DHT dht(DHTPIN, DHTTYPE);

// WiFi
const char* ssid     = "Wokwi-GUEST";
const char* password = "";

// ThingsBoard MQTT
const char* tb_server = "mqtt.thingsboard.cloud";
const int   tb_port   = 1883;
const char* tb_token  = "20ye402gcaqwx4byiiwj";  // Replace with your token

WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.print("Connecting to WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" connected!");
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Connecting to ThingsBoard... ");
    if (client.connect("ESP32Client", tb_token, NULL)) {
      Serial.println("connected!");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" retrying in 5s");
      delay(5000);
    }
  }
}

void setup() {
  setup_wifi();
  client.setServer(tb_server, tb_port);
  dht.begin();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  float temp = dht.readTemperature();
  float hum  = dht.readHumidity();

  if (isnan(temp) || isnan(hum)) {
    Serial.println("Failed to read from DHT sensor!");
    delay(2000);
    return;
  }

  char payload[64];
  snprintf(payload, sizeof(payload), "{\"temperature\": %.2f, \"humidity\": %.2f}", temp, hum);

  client.publish("v1/devices/me/telemetry", payload);
  Serial.print("Sent to ThingsBoard: ");
  Serial.println(payload);

  delay(5000);
}