#include <WiFi.h>
#include <PubSubClient.h>
#include "DHT.h"

// ===== Konfigurasi WiFi =====
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// ===== Konfigurasi MQTT =====
const char* mqtt_server = "test.mosquitto.org"; 
const int mqtt_port = 1883;
WiFiClient espClient;
PubSubClient client(espClient);

// ===== Konfigurasi DHT22 =====
#define DHTPIN 4       
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// ===== Konfigurasi LED =====
#define LED_PIN 2   // LED onboard ESP32

// ===== Topic MQTT =====
const char* topic_temp = "esp32/suhu";
const char* topic_hum  = "esp32/kelembapan";
const char* topic_led  = "esp32/led";   // untuk kontrol LED

void setup_wifi() {
  delay(10);
  Serial.print("Menghubungkan ke WiFi: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi terhubung!");
  Serial.print("IP ESP32: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  Serial.print("Pesan dari topic ");
  Serial.print(topic);
  Serial.print(" : ");
  Serial.println(message);

  if (String(topic) == topic_led) {
    if (message == "ON") {
      digitalWrite(LED_PIN, HIGH);
      Serial.println("LED ON");
    } else if (message == "OFF") {
      digitalWrite(LED_PIN, LOW);
      Serial.println("LED OFF");
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Menghubungkan ke MQTT...");
    if (client.connect("ESP32ClientDashboard")) {
      Serial.println("Terhubung!");
      client.subscribe(topic_led);
    } else {
      Serial.print("Gagal, rc=");
      Serial.println(client.state());
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);
  dht.begin();
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  float suhu = dht.readTemperature();
  float kelembapan = dht.readHumidity();

  if (!isnan(suhu) && !isnan(kelembapan)) {
    char buffer[10];
    dtostrf(suhu, 4, 2, buffer);
    client.publish(topic_temp, buffer);

    dtostrf(kelembapan, 4, 2, buffer);
    client.publish(topic_hum, buffer);

    Serial.print("Publish suhu: ");
    Serial.println(suhu);
    Serial.print("Publish kelembapan: ");
    Serial.println(kelembapan);
  }

  delay(5000);
}