#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";  
const char* password = "";

const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;
const char* mqtt_topic = "Brunobrabo/led";
const char* client_id = "ESP32PainelTeste";

WiFiClient espClient;
PubSubClient client(espClient);

const int ledPin = 13;  // LED interno do ESP32 no Wokwi

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Mensagem recebida em ");
  Serial.print(topic);
  Serial.print(": ");

  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  message.trim();      
  message.toUpperCase(); 

  Serial.println(message);

  if (message == "LIGADO" || message == "ON" || message == "1") {
    digitalWrite(ledPin, HIGH);
    Serial.println("LED LIGADO");
  } else if (message == "DESLIGADO" || message == "OFF" || message == "0") {
    digitalWrite(ledPin, LOW);
    Serial.println("LED DESLIGADO");
  }
}

void setup() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.println("Conectando ao WiFi...");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi conectado!");

  pinMode(ledPin, OUTPUT);

  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Conectando ao broker MQTT...");
    if (client.connect(client_id)) {
      Serial.println("Conectado!");
      client.subscribe(mqtt_topic);
    } else {
      Serial.print("Falha, rc=");
      Serial.print(client.state());
      delay(2000);
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}