#include <WiFi.h>
#include <PubSubClient.h>
#include "DHT.h"

#define DHTPIN 15        // pin DHT22 di ESP32
#define DHTTYPE DHT22    // jenis sensor
#define LEDPIN 2         // LED di GPIO2 (bisa diganti sesuai rangkaian)

DHT dht(DHTPIN, DHTTYPE);

const char* ssid = "Wokwi-GUEST";  // WiFi bawaan Wokwi
const char* password = "";         // password kosong

const char* mqtt_server = "pings-112.cloud.shiftr.io";
const int   mqtt_port   = 1883; // TCP (bukan wss)
const char* mqtt_user   = "pings-112";
const char* mqtt_pass   = "pinsss";

WiFiClient espClient;
PubSubClient client(espClient);

// callback kalau ada pesan masuk
void callback(char* topic, byte* message, unsigned int length) {
  String msg;
  for (int i = 0; i < length; i++) {
    msg += (char)message[i];
  }
  Serial.print("Pesan [");
  Serial.print(topic);
  Serial.print("] : ");
  Serial.println(msg);

  // kontrol LED sesuai topic
  if (String(topic) == "led/onot" && msg == "ON") {
    digitalWrite(LEDPIN, HIGH);
    Serial.println("LED -> ON");
  }
  if (String(topic) == "led/offt" && msg == "OFF") {
    digitalWrite(LEDPIN, LOW);
    Serial.println("LED -> OFF");
  }
}

void setup_wifi() {
  Serial.println("Connecting to WiFi...");
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi connected!");
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESP32Client", mqtt_user, mqtt_pass)) {
      Serial.println("connected!");
      // subscribe ke topik kontrol LED
      client.subscribe("led/onot");
      client.subscribe("led/offt");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5s");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  dht.begin();

  pinMode(LEDPIN, OUTPUT);
  digitalWrite(LEDPIN, LOW);

  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback); // penting biar bisa terima pesan
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // publish data sensor setiap 5 detik
  static unsigned long lastMsg = 0;
  if (millis() - lastMsg > 5000) {
    lastMsg = millis();
    float h = dht.readHumidity();
    float t = dht.readTemperature();

    if (isnan(h) || isnan(t)) {
      Serial.println("Gagal baca sensor DHT!");
      return;
    }

    // format JSON
    String payload = "{ \"suhu\": " + String(t) + ", \"kelembapan\": " + String(h) + " }";
    Serial.println("Kirim data: " + payload);

    client.publish("sensor", payload.c_str());
  }
}