#include <WiFi.h>
#include "ThingSpeak.h"
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include "DHT.h"

#define DHTPIN 4 // Pin ESP yang tersambung ke pin Data DHT22 (pin 4)
#define DHTTYPE DHT22 // jenis sensor DHT 22 (AM2302, AM2321)
DHT dht(DHTPIN, DHTTYPE);

float hum = 0;   // variabel untuk menyimpan nilai kelembaban
float temp = 0;  // variabel untuk menyimpan nilai suhu
float hic = 0;   // heat index dalam celcius

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire);

char ssid[] = "Wokwi-GUEST"; // Wokwi Wifi
char pass[] = ""; // Blank Password
int keyIndex = 0; // your network key Index number (needed only for WEP)
WiFiClient client;

unsigned long myChannelNumber = 3068657;
const char * myWriteAPIKey = "K8H8QX1XAKO820K0";

unsigned long previousMillis = 0;
const long ts_update_interval = 20000; // update data setiap 20s

// 'thermometer', 55x55px
const unsigned char thermo[] PROGMEM = {
  // isi array bitmap thermometer...
};

const unsigned char wifi_icon[] PROGMEM = {
  // isi array bitmap wifi connected...
};

const unsigned char wifi_dc[] PROGMEM = {
  // isi array bitmap wifi disconnected...
};

const unsigned char Update_OK[] PROGMEM = {
  // isi array bitmap update OK...
};

const unsigned char Update_NOK[] PROGMEM = {
  // isi array bitmap update NOK...
};

// Fungsi penampil status WiFi di OLED
void tampilWifiStatus() {
  if(WiFi.status() == WL_CONNECTED){
      Serial.println("\n Connected!");
      display.clearDisplay();
      display.setTextSize(1);
      display.drawBitmap(52, 15, wifi_icon, 16, 16, WHITE);
      display.setCursor(33,38); display.print("Connected!");
      display.display();
  }else{
      display.clearDisplay();
      display.setTextSize(1);
      display.drawBitmap(52, 15, wifi_dc, 16, 16, WHITE);
      display.setCursor(20,38); display.print("Wifi Connection");
      display.setCursor(36,48); display.print("Failed!");
      display.display();
  }
  delay(3000);
}

// Fungsi koneksi WiFi
void ConnectWIFI(){
  if(WiFi.status() != WL_CONNECTED){
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    WiFi.begin(ssid, pass);
    int i=0;
    int a=0;
    while(WiFi.status() != WL_CONNECTED){
      Serial.print(".");
      display.clearDisplay();
      display.setTextSize(1);
      if(a==0){
        display.drawBitmap(52, 15, wifi_icon, 16, 16, WHITE);
        a=1;
      }else{
        display.drawBitmap(52, 15, wifi_icon, 16, 16, BLACK);
        a=0;
      }
      display.setCursor(25,38); display.print("Connecting ...");
      display.display();
      delay(1000);
      ++i;
      if(i==30){
        i=0;
        Serial.println("\n Failed to Connect.");
        break;
      }
    }
  }
}

void setup() {
  Serial.begin(9600);
  Serial.println(F("Temp & Humid Monitoring System"));
  dht.begin();

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }

  // just intro
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(38,20); display.println(F("ThinkSpeak"));
  display.setCursor(25,35); display.println(F("Temp-Hum Monitor"));
  display.display(); //tampilkan data
  delay(3000);

  WiFi.mode(WIFI_STA);
  ThingSpeak.begin(client); // Initialize ThingSpeak
  ConnectWIFI();
}

void loop() {
  hum = dht.readHumidity();
  temp = dht.readTemperature(); // membaca suhu dalam Celsius
  // temp = dht.readTemperature(true); //suhu dalam Fahrenheit

  // Check if any reads failed and exit early (to try again).
  if (isnan(hum) || isnan(temp)) {
    Serial.println(F("Gagal mendapat data dari sensor DHT!"));
    return;
  }

  // Compute heat index in Celsius (isFahrenheit = false)
  hic = dht.computeHeatIndex(temp, hum, false);

  display.clearDisplay();
  display.drawBitmap(0, 5, thermo, 55, 55, WHITE);
  display.setTextSize(1);
  display.setCursor(55,25); display.print(temp); display.print(" C");
  display.setCursor(55,40); display.print(hum); display.print(" %");
  if(WiFi.status() != WL_CONNECTED){
    display.drawBitmap(110, 0, wifi_dc, 16, 16, WHITE);
  }else{
    display.drawBitmap(110, 0, wifi_icon, 16, 16, WHITE);
  }
  display.display();

  // Tampilkan status WiFi setiap siklus utama
  tampilWifiStatus();

  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= ts_update_interval) {
    previousMillis = currentMillis;
    if(WiFi.status() != WL_CONNECTED){
      Serial.print("Attempting to connect to SSID: ");
      Serial.println(ssid);
      WiFi.begin(ssid, pass);
      int i=0;
      while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
        ++i;
        if (i==20){
          i=0;
          Serial.println("\n Failed to Connect.");
          break;
        }
      }
    }
    ThingSpeak.setField(1, hum);   //field humidity
    ThingSpeak.setField(2, temp);  //field temperature
    ThingSpeak.setField(3, hic);   //field heat_index

    // write to the ThingSpeak channel
    int x = ThingSpeak.writeFields(myChannelNumber, myWriteAPIKey);
    if(x == 200){
      Serial.println("Sukses Update Chanel.");
      display.drawBitmap(90, 0, Update_OK, 16, 16, WHITE);
    }else{
      Serial.println("Update Chanel Bermasalah. HTTP error code " + String(x));
      display.drawBitmap(90, 0, Update_NOK, 16, 16, WHITE);
    }
    display.display();
    delay(2000);
  }
}