#include <WiFi.h>
#include <PubSubClient.h>

#define LED_PIN 14

const char *mqtt_broker = "yandex-cpp.cloud.shiftr.io";
const char *topic = "light";
const char *mqtt_username = "yandex-cpp";
const char *mqtt_password = "O1UNfc6vB9DtjEvl";
const int mqtt_port = 1883;
const char *client_name = "lamp-esp32";

WiFiClient espClient;
PubSubClient client(espClient);

String getMessage(byte *payload, unsigned int length){
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  return message;
}

void connectWiFi(){
  Serial.print("Connecting to WiFi");
  WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Connected!");
}

void connectMQTT(){
  Serial.print("Connecting to MQTT");
  while (!client.connected()) {
          if (client.connect(client_name, mqtt_username, mqtt_password)) {
              Serial.println(" Connected!");
          } else {
              Serial.print(".");
              delay(1000);
          }
      }
}

void callback(char *topic, byte *payload, unsigned int length) {
  String topicStr = String(topic);
  String message = getMessage(payload, length);
  Serial.print("Got message `");
  Serial.print(message);
  Serial.print("` into topic: `");
  Serial.print(topicStr);
  Serial.println("`");
  if (topicStr == "light"){
    if (message == "on") {
      digitalWrite(LED_PIN, HIGH);
    }
    else if (message == "off") {
      digitalWrite(LED_PIN, LOW);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);
  connectWiFi();
  client.setServer(mqtt_broker, mqtt_port);
  client.setCallback(callback);
  client.setKeepAlive(10);
  connectMQTT();
  client.subscribe(topic);
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) {
    connectWiFi();
  }
  if (!client.connected()) {
    connectMQTT();
  }
  client.loop();
  delay(10);
}