/*
  Getting intermediate values of the variable while in edit mode via preview callbacks and lighting up LEDs in response.

  Simple one page menu with select to choose mode of operation. In first mode byte range spinner is used to determine
  which one of 3 LEDs will light up, in second mode 3 LEDs display binary representation of a decimal number
  (set via editable int variable).

  U8g2lib library is used to draw menu.
  KeyDetector library (version 1.2.0 or later) is used to detect rotary encoder operation.
  
  Additional info available on GitHub:
  https://github.com/Spirik/GEM
  
  This example code is in the public domain.
*/

#include <GEM_u8g2.h>
#include <KeyDetector.h>

// ====================

// Pins LEDs are connected to
const byte leds[] = {5, 6, 7};
const byte ledsCount = sizeof(leds)/sizeof(byte);

// Define signal identifiers for three outputs of encoder (channel A, channel B and a push-button)
#define KEY_A 1
#define KEY_B 2
#define KEY_C 3

// Pins encoder is connected to
const byte channelA = 2;
const byte channelB = 3;
const byte buttonPin = 4;

byte chanB = HIGH; // Variable to store Channel B readings

// Array of Key objects that will link GEM key identifiers with dedicated pins
// (it is only necessary to detect signal change on a single channel of the encoder, either A or B;
// order of the channel and push-button Key objects in an array is not important)
Key keys[] = {{KEY_A, channelA}, {KEY_C, buttonPin}};
//Key keys[] = {{KEY_C, buttonPin}, {KEY_A, channelA}};

// Create KeyDetector object
// KeyDetector myKeyDetector(keys, sizeof(keys)/sizeof(Key));
// To account for switch bounce effect of the buttons (if occur) you may want to specify debounceDelay
// as the third argument to KeyDetector constructor.
// Make sure to adjust debounce delay to better fit your rotary encoder.
// Also it is possible to enable pull-up mode when buttons wired with pull-up resistors (as in this case).
// Analog threshold is not necessary for this example and is set to default value 16.
KeyDetector myKeyDetector(keys, sizeof(keys)/sizeof(Key), /* debounceDelay= */ 5, /* analogThreshold= */ 16, /* pullup= */ true);

bool secondaryPressed = false;  // If encoder rotated while key was being pressed; used to prevent unwanted triggers
bool cancelPressed = false;  // Flag indicating that Cancel action was triggered, used to prevent it from triggering multiple times
const int keyPressDelay = 1000; // How long to hold key in pressed state to trigger Cancel action, ms
long keyPressTime = 0; // Variable to hold time of the key press event
long now; // Variable to hold current time taken with millis() function at the beginning of loop()

// Create an instance of the U8g2 library.
// Use constructor that matches your setup (see https://github.com/olikraus/u8g2/wiki/u8g2setupcpp for details).
// This instance is used to call all the subsequent U8g2 functions (internally from GEM library,
// or manually in your sketch if it is required).
// Please update the pin numbers according to your setup. Use U8X8_PIN_NONE if the reset pin is not connected
U8G2_SH1106_128X64_NONAME_1_HW_I2C u8g2(U8G2_R0, /* reset=*/ U8X8_PIN_NONE);

// Create variable that will be editable through option select and create associated option select.
byte mode = 0;
SelectOptionByte selectModeOptions[] = {{"Index", 0}, {"Number", 1}};
GEMSelect selectMode(sizeof(selectModeOptions)/sizeof(SelectOptionByte), selectModeOptions);

// byte spinner
byte index = 1;
GEMSpinnerBoundariesByte spinnerByteBoundaries = { .step = 1, .min = 1, .max = 3 };
GEMSpinner spinnerByte(spinnerByteBoundaries, GEM_LOOP);

// Create variables that will be editable through the menu and assign them initial values
int number = 0;

// Create menu item for option select with applyMode() callback function
void applyMode(); // Forward declaration of save callback
GEMItem menuItemMode("Mode:", mode, selectMode, applyMode);

// Ceate menu item linked to index variable, with saveIndex() callback function 
void saveIndex(); // Forward declaration of save callback
GEMItem menuItemIndex("Index:", index, spinnerByte, saveIndex);

// Create menu item linked to number variable, with saveNumber() callback function 
void saveNumber(); // Forward declaration of save callback
GEMItem menuItemNumber("Number:", number, saveNumber);

// Create menu page object of class GEMPage. Menu page holds menu items (GEMItem) and represents menu level.
// Menu can have multiple menu pages (linked to each other) with multiple menu items each
GEMPage menuPageMain("Preview Callbacks with LEDs!"); // Main page

// Create menu object of class GEM_u8g2. Supply its constructor with reference to u8g2 object we created earlier
GEM_u8g2 menu(u8g2, GEM_POINTER_ROW, GEM_ITEMS_COUNT_AUTO);
// Which is equivalent to the following call (you can adjust parameters to better fit your screen if necessary):
// GEM_u8g2 menu(u8g2, /* menuPointerType= */ GEM_POINTER_ROW, /* menuItemsPerScreen= */ GEM_ITEMS_COUNT_AUTO, /* menuItemHeight= */ 10, /* menuPageScreenTopOffset= */ 10, /* menuValuesLeftOffset= */ 86);

void setup() {
  // Pin modes
  for (byte i = 0; i < ledsCount; i++) {
    pinMode(leds[i], OUTPUT);
  }
  pinMode(channelA, INPUT_PULLUP);
  pinMode(channelB, INPUT_PULLUP);
  pinMode(buttonPin, INPUT_PULLUP);

  // Turn off LEDs
  resetLEDs();

  // Serial communication setup
  Serial.begin(115200);

  // U8g2 library init.
  u8g2.begin();
  
  // Turn inverted order of characters during edit mode on (feels more natural when using encoder)
  menu.invertKeysDuringEdit(true);
  
  // Apply initially selected mode
  applyMode();

  // Menu init, setup and draw
  menu.init();
  setupMenu();
  menu.drawMenu();

  Serial.println("Initialized");
}

void setupMenu() {
  menuItemMode.setPreviewCallback(previewMode);
  menuItemIndex.setPreviewCallback(previewIndex);
  menuItemNumber.setPreviewCallback(previewNumber);

  // Add menu items to menu page
  menuPageMain
    .addMenuItem(menuItemMode)
    .addMenuItem(menuItemIndex)
    .addMenuItem(menuItemNumber);

  // Add menu page to menu and set it as current
  menu.setMenuPageCurrent(menuPageMain);
}

void loop() {
  // Get current time to use later on
  now = millis();

  // If menu is ready to accept button press...
  if (menu.readyForKey()) {
    chanB = digitalRead(channelB); // Reading Channel B signal beforehand to account for possible delays due to polling nature of KeyDetector algorithm
    // ...detect key press using KeyDetector library
    // and pass pressed button to menu
    myKeyDetector.detect();
  
    switch (myKeyDetector.trigger) {
      case KEY_A:
        // Signal from Channel A of encoder was detected
        if (chanB == LOW) {
          // If channel B is low then the knob was rotated CCW
          if (myKeyDetector.current == KEY_C) {
            // If push-button was pressed at that time, then treat this action as GEM_KEY_LEFT,...
            // Serial.println("Rotation CCW with button pressed");
            menu.registerKeyPress(GEM_KEY_LEFT);
            // Button was in a pressed state during rotation of the knob, acting as a modifier to rotation action
            secondaryPressed = true;
          } else {
            // ...or GEM_KEY_UP otherwise
            // Serial.println("Rotation CCW");
            menu.registerKeyPress(GEM_KEY_UP);
          }
        } else {
          // If channel B is high then the knob was rotated CW
          if (myKeyDetector.current == KEY_C) {
            // If push-button was pressed at that time, then treat this action as GEM_KEY_RIGHT,...
            // Serial.println("Rotation CW with button pressed");
            menu.registerKeyPress(GEM_KEY_RIGHT);
            // Button was in a pressed state during rotation of the knob, acting as a modifier to rotation action
            secondaryPressed = true;
          } else {
            // ...or GEM_KEY_DOWN otherwise
            // Serial.println("Rotation CW");
            menu.registerKeyPress(GEM_KEY_DOWN);
          }
        }
        break;
      case KEY_C:
        // Button was pressed
        // Serial.println("Button pressed");
        // Save current time as a time of the key press event
        keyPressTime = now;
        break;
    }
    switch (myKeyDetector.triggerRelease) {
      case KEY_C:
        // Button was released
        // Serial.println("Button released");
        if (!secondaryPressed) {
          // If button was not used as a modifier to rotation action...
          if (now <= keyPressTime + keyPressDelay) {
            // ...and if not enough time passed since keyPressTime,
            // treat key that was pressed as Ok button
            menu.registerKeyPress(GEM_KEY_OK);
          }
        }
        secondaryPressed = false;
        cancelPressed = false;
        break;
    }
    // After keyPressDelay passed since keyPressTime
    if (now > keyPressTime + keyPressDelay) {
      switch (myKeyDetector.current) {
        case KEY_C:
          if (!secondaryPressed && !cancelPressed) {
            // If button was not used as a modifier to rotation action, and Cancel action was not triggered yet
            // Serial.println("Button remained pressed");
            // Treat key that was pressed as Cancel button
            menu.registerKeyPress(GEM_KEY_CANCEL);
            cancelPressed = true;
          }
          break;
      }
    }
  }
}

/* LEDs operation */

void resetLEDs() {
  for (byte i = 0; i < ledsCount; i++) {
    digitalWrite(leds[i], LOW);
  }
}

void lightIndex(byte ind) {
  for (byte i = 0; i < ledsCount; i++) {
    digitalWrite(leds[i], i == ind - 1);
  }

  Serial.print("Index: ");
  Serial.println(ind);
}

void lightBinary(int num) {
  if (num < 0) {
    num = 0;
  } else if (num > 7) {
    num = 7;
  }

  byte digits[ledsCount];

  for (byte i = 0; i < ledsCount; i++) {
      digits[i] = (num >> i) & 1;
  }

  for (byte i = 0; i < ledsCount; i++) {
    digitalWrite(leds[i], digits[i] == 1);
  }

  Serial.print("Binary: ");
  for (byte i = ledsCount; i > 0; i--) {
    Serial.print(digits[i - 1]);
  }
  Serial.println();
}

/* Preview callbacks */

void previewMode(GEMPreviewCallbackData previewData) {
  const int selectedIndex = previewData.previewSelectNum;
  if (selectedIndex != -1) {
    Serial.print(".previewSelectNum: ");
    Serial.print(selectedIndex);
    Serial.print(" | Name: ");
    Serial.print(selectModeOptions[selectedIndex].name);
    Serial.print(" | Val: ");
    Serial.println(selectModeOptions[selectedIndex].val_byte);
    if (selectModeOptions[selectedIndex].val_byte == 0) {
      lightIndex(index);
    } else {
      lightBinary(number);
    }
  } else {
    Serial.print("Cancel. Original value remains: ");
    Serial.println(mode);
    applyMode();
  }
}

void previewIndex(GEMPreviewCallbackData previewData) {
  const int selectedIndex = previewData.previewSelectNum;
  if (selectedIndex != -1) {
    Serial.print(".previewSelectNum: ");
    Serial.print(selectedIndex);
    Serial.print(" | Byte: ");
    Serial.println(previewData.previewValByte);
    lightIndex(previewData.previewValByte);
  } else {
    Serial.print("Cancel. Original value remains: ");
    Serial.println(index);
    lightIndex(index);
  }
}

void previewNumber(GEMPreviewCallbackData previewData) {
  const char* previewString = previewData.previewString;
  if (previewString != nullptr) {
    Serial.print(".previewString: ");
    Serial.print(previewString);
    Serial.print(" | Int: ");
    Serial.println(previewData.previewValInt);
    lightBinary(previewData.previewValInt);
  } else {
    Serial.print("Cancel. Original value remains: ");
    Serial.println(number);
    lightBinary(number);
  }
}

/* Save callbacks */

void applyMode() {
  Serial.print("Mode: ");
  Serial.println(mode);
  menuItemIndex.hide(mode);
  menuItemNumber.hide(!mode);
  if (mode) {
    lightBinary(number);
  } else {
    lightIndex(index);
  }
}

void saveIndex() {
  Serial.print("Index: ");
  Serial.println(index);
  lightIndex(index);
}

void saveNumber() {
  if (number < 0) {
    number = 0;
  } else if (number > 7) {
    number = 7;
  }
  Serial.print("Number: ");
  Serial.println(number);
  lightBinary(number);
}