#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// Configuración OLED
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Configuración WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Configuración MQTT
const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;
const char* topic = "banda/control";

WiFiClient espClient;
PubSubClient client(espClient);

// Variables de control
bool bandaActiva = false;
unsigned long lastMsg = 0;

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Conectando a ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.println("Dirección IP: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  
  Serial.print("Mensaje recibido: ");
  Serial.println(message);

  if (message == "ON") {
    bandaActiva = true;
  } else if (message == "OFF") {
    bandaActiva = false;
  }
  
  actualizarOLED();
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Intentando conexión MQTT...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    
    if (client.connect(clientId.c_str())) {
      Serial.println("conectado");
      client.subscribe(topic);
    } else {
      Serial.print("falló, rc=");
      Serial.print(client.state());
      Serial.println(" intentando en 5 segundos");
      delay(5000);
    }
  }
}

void actualizarOLED() {
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  
  display.setCursor(0,0);
  display.println("Banda Transportadora");
  display.println("====================");
  
  display.print("WiFi: ");
  display.println(WiFi.status() == WL_CONNECTED ? "Conectado" : "Desconectado");
  
  display.print("MQTT: ");
  display.println(client.connected() ? "Conectado" : "Desconectado");
  
  display.print("Estado: ");
  display.println(bandaActiva ? "ENCENDIDA" : "DETENIDA");
  
  display.display();
}

void setup() {
  Serial.begin(115200);
  
  // Inicializar OLED
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("Error en pantalla OLED"));
    for(;;);
  }
  display.display();
  delay(2000);
  display.clearDisplay();
  
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
  
  actualizarOLED();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // Actualizar cada 2 segundos
  if (millis() - lastMsg > 2000) {
    lastMsg = millis();
    actualizarOLED();
  }
}