#include <Ticker.h>
#include <WiFi.h>
#include <PubSubClient.h>

Ticker aiTimer;  // Timer
const char *mqttServer = "broker.hivemq.com";
const int mqttPort = 1883;

const char* topicStatus = "np/std1/sensor/status";
const char* topicAnalog = "np/std1/sensor/analog";

WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);

void reconnect() {
  while (!mqttClient.connected()) {
    Serial.printf("Attempting MQTT connection %s...",
                  mqttServer);
    String clientID = "np25" + String(random(0xffff), HEX);

    if (mqttClient.connect(clientID.c_str())) {
      Serial.printf("connected\n");
    } 
    else {
      Serial.printf("failed, rc=%d. Retring again in 5s ...\n",
                    mqttClient.state());
      delay(5000);
    }
  }
}

void scanDI() {
  static bool lastButtonState = LOW;
  bool buttonState = digitalRead(4);
  if (buttonState != lastButtonState) {
    String status = buttonState ? "Pressed" : "Released";
    mqttClient.publish(topicStatus, status.c_str());
    lastButtonState = buttonState;
  }
}

void scanAI() {
  int potValue = analogRead(34);
  String analogMsg = String(potValue);
  mqttClient.publish(topicAnalog, analogMsg.c_str());
}

void setup() {
  Serial.begin(115200);
  Serial.println("7.1 Basic Sensor Publishing");

  WiFi.mode(WIFI_STA);
  WiFi.begin("Wokwi-GUEST", "");
  WiFi.setAutoReconnect(true);

  Serial.print("Connecting to WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.printf("\nConnected! IP: %s\n",
                WiFi.localIP().toString().c_str());

  pinMode(4, INPUT_PULLDOWN);
  mqttClient.setServer(mqttServer, mqttPort);
  aiTimer.attach(2, scanAI);
}

void loop() {
  if (!mqttClient.connected()) {
    reconnect();
  }
  mqttClient.loop(); // Needed for keep-alive

  scanDI();
  delay(10);
}