#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <ESP32Servo.h>
#include <ArduinoJson.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;
const char* topic_lamp1  = "iot/dashboard/lamp1";
const char* topic_lamp2  = "iot/dashboard/lamp2";
const char* topic_sensor = "iot/dashboard/sensor";
const char* topic_servo  = "iot/dashboard/servo";

#define LAMP1_PIN 2      
#define LAMP2_PIN 19    
#define DHT_PIN   4
#define SERVO_PIN 13
#define DHTTYPE   DHT22

WiFiClient espClient;
PubSubClient client(espClient);
DHT dht(DHT_PIN, DHTTYPE);
Servo myServo;

bool lamp1Status = false;
bool lamp2Status = false;
int servoAngle = 0;
unsigned long lastMsg = 0;

void setup_wifi() {
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi connected");
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  Serial.print("Message [");
  Serial.print(topic);
  Serial.print("]: ");
  Serial.println(message);

  // Logika untuk Lampu 1
  if (String(topic) == topic_lamp1) {
    if (message == "ON") {
      digitalWrite(LAMP1_PIN, HIGH);
      lamp1Status = true;
      Serial.println("Lamp 1 ON");
    } 
    else if (message == "OFF") {
      digitalWrite(LAMP1_PIN, LOW);
      lamp1Status = false;
      Serial.println("Lamp 1 OFF");
    }
  }

  // Logika untuk Lampu 2
  if (String(topic) == topic_lamp2) {
    if (message == "ON") {
      digitalWrite(LAMP2_PIN, HIGH);
      lamp2Status = true;
      Serial.println("Lamp 2 ON");
    } 
    else if (message == "OFF") {
      digitalWrite(LAMP2_PIN, LOW);
      lamp2Status = false;
      Serial.println("Lamp 2 OFF");
    }
  }

  if (String(topic) == topic_servo) {
    servoAngle = message.toInt();
    if (servoAngle >= 0 && servoAngle <= 180) {
      myServo.write(servoAngle);
      Serial.print("Servo angle: ");
      Serial.println(servoAngle);
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-" + String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Subscribe ke kedua topik lampu
      client.subscribe(topic_lamp1);
      client.subscribe(topic_lamp2);
      client.subscribe(topic_servo);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" retry in 5s");
      delay(5000);
    }
  }
}

void publishSensorData() {
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();

  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read DHT!");
    return;
  }

  StaticJsonDocument<256> doc; // Buffer sedikit diperbesar
  doc["temperature"] = temperature;
  doc["humidity"] = humidity;
  doc["servo"] = servoAngle;
  // Kirim status kedua lampu
  doc["lamp1"] = lamp1Status ? "ON" : "OFF";
  doc["lamp2"] = lamp2Status ? "ON" : "OFF";

  char buffer[256];
  serializeJson(doc, buffer);
  client.publish(topic_sensor, buffer);

  Serial.printf("Temp: %.2f °C | Hum: %.2f %%\n", temperature, humidity);
}

void setup() {
  Serial.begin(115200);

  pinMode(LAMP1_PIN, OUTPUT);
  pinMode(LAMP2_PIN, OUTPUT);
  digitalWrite(LAMP1_PIN, LOW);
  digitalWrite(LAMP2_PIN, LOW);

  dht.begin();
  myServo.attach(SERVO_PIN);
  myServo.write(0);

  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  if (millis() - lastMsg > 2000) {
    lastMsg = millis();
    publishSensorData();
  }
}