#include "RTClib.h"
#include "LiquidCrystal_I2C.h"
#include "EEPROM.h"
#include "IRremote.hpp"

// der Pin, an dem der Infrarot-Empfänger angeschlossen ist
int EmpfaengerPin = 8;

// 4-zeiliges LCD
LiquidCrystal_I2C lcd(0x27,20,4);

// Name des RTC-Moduls 
RTC_DS3231 rtc; 

int Lautsprecher = 5;

// Beginn der Weckzeit
int StundeWeckzeit = 6;
int MinuteWeckzeit = 0;

// Uhrzeiten Aus/-einschaltung Hintergrundbeleuchtung
int ZeitBeleuchtungAus = 22;
int ZeitBeleuchtungEin = 7;

// Sekunden anzeigen ein/aus
bool SekundenAnzeigen = true;

// Dauer des Signal in Sekunden
int DauerWecksignal = 3;
bool TonSekunde = false;
bool WeckerEinAus = true;

// Zeit messen für Ticken der Uhr
long Startzeit;
long ZeitJetzt;

void setup()
{
  // Infrarot-Empfänger starten
  IrReceiver.begin(EmpfaengerPin);

  Serial.begin(9600);
 
  // auf serielle Verbindung warten
  while (!Serial) {;}
  delay(1000);

  rtc.begin();
  /*
    wenn Datum und Zeit nicht korrekt -> Datum/Zeit setzen
    Jahr, Monat, Tag, Stunde, Minute, Sekunde
    keine führende 0 setzen
    rtc.adjust(DateTime(2025, 4, 14, 16, 42, 30));
  */
  // rtc.adjust(DateTime(2025, 4, 14, 16, 42, 30));

  // Zeitpunkt des Kompilierens als aktuelle Zeit setzen
  // rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));

  // LCD starten
  lcd.init();
  lcd.backlight();

  Startzeit = millis();
}

void loop()
{
  String Stunde, Minute, Weckzeit;

  // aktuelle Zeit lesen
  DateTime aktuell = rtc.now();

  if (IrReceiver.decode()) 
  {
    // resume -> nächsten Wert lesen
    IrReceiver.resume();
    if (IrReceiver.decodedIRData.command > 0 && IrReceiver.decodedIRData.command < 95) 
    {
      delay(200);

      Serial.println(IrReceiver.decodedIRData.command);

      // Pfeil oben -> Stunden ++
      if (IrReceiver.decodedIRData.command == 70)
      {
        if (StundeWeckzeit >= 23) StundeWeckzeit = 0;
        else StundeWeckzeit ++;  
      }
      
      // Pfeil unten Stunden --
      if (IrReceiver.decodedIRData.command == 21)
      {
        if (StundeWeckzeit == 0) StundeWeckzeit = 23;
        else StundeWeckzeit --;
      }

      // Pfeil rechts -> Minuten ++
      if (IrReceiver.decodedIRData.command == 67)
      {
        if (MinuteWeckzeit >= 59) MinuteWeckzeit = 0;
        else MinuteWeckzeit ++;
      }
      
      // Pfeil links -> Minuten --
      if (IrReceiver.decodedIRData.command == 68)
      {
        if (MinuteWeckzeit == 0) MinuteWeckzeit = 59;
        else MinuteWeckzeit --;
      }

      // OK -> Wecker ein/aus
      if (IrReceiver.decodedIRData.command == 64)
      {
        WeckerEinAus = !WeckerEinAus;
      }

      // # -> Hintergrundbeleuchtung aus
      if (IrReceiver.decodedIRData.command == 74)
      {
        lcd.setBacklight(false);
      }

      // # -> Hintergrundbeleuchtung ein
      if (IrReceiver.decodedIRData.command == 66)
      {
        lcd.setBacklight(true);
      }
    }
  }

  // Wochentag, Datum und Zeit anzeigen
  lcd.setCursor(0, 0);

  /*
    Wochentag anzeigen
    0 = Sonntag
    1 = Montag
    ...
    6 = Samstag
  */
  switch (aktuell.dayOfTheWeek())
  {
    case 0:
      lcd.print("Sonntag    ");
      break;
    case 1:
      lcd.print("Montag     ");
      break;
    case 2:
      lcd.print("Dienstag    ");
      break;
    case 3:
      lcd.print("Mittwoch    ");
      break;
    case 4:
      lcd.print("Donnerstag");
      break;
    case 5:
      lcd.print("Freitag     ");
      break;
    case 6:
      lcd.print("Samstag     ");
      break;
  }

  lcd.setCursor(0, 1);
  lcd.print(String(aktuell.day()) + ".");

  // Monatsnamen anzeigen
  lcd.print(" ");

  switch (aktuell.month())
  {
    case 1:
      lcd.print("Januar");
      break;
    case 2:
      lcd.print("Februar");
      break;
    case 3:
      lcd.print("M\341rz");
      break;
    case 4:
      lcd.print("April");
      break;
    case 5:
      lcd.print("Mai");
      break;
    case 6:
      lcd.print("Juni");
      break;
    case 7:
      lcd.print("Juli");
      break;
    case 8:
      lcd.print("August");
      break;
    case 9:
      lcd.print("September");
      break;
    case 10:
      lcd.print("Oktober");
      break;
    case 11:
      lcd.print("November");
      break;
    case 12:
      lcd.print("Dezember");
      break;
  }
  lcd.print(" ");

  lcd.print(String(aktuell.year()));
  lcd.setCursor(0, 2);

  // wenn Stunden < 10 -> führende 0 setzen
  if (aktuell.hour() < 10) lcd.print("0");
  lcd.print(String(aktuell.hour()));
  lcd.print(':');

  // wenn Minuten < 10 -> führende 0 setzen
  if (aktuell.minute() < 10) lcd.print("0");
  lcd.print(String(aktuell.minute()));

  if(SekundenAnzeigen)
  {
    lcd.print(':');
    
    // wenn Sekunden < 10 -> führende 0 setzen
    if (aktuell.second() < 10) lcd.print("0");
    lcd.print(String(aktuell.second()));
  }

  // Steuerung der Hintergrundbeleuchtung
  if(aktuell.hour() == ZeitBeleuchtungAus) lcd.setBacklight(false);
  if(aktuell.hour() == ZeitBeleuchtungEin) lcd.setBacklight(true);

  if (WeckerEinAus) lcd.print(" Wecker ein");
  else lcd.print(" Wecker aus");

  /*
    Weckzeit formatieren -> führende 0 ergänzen
    4 mögliche Fälle
    Stunde < 10 Minute < 10
    Stunde < 10 Minute > 9
    Stunde > 10 Minute < 10
    Stunde > 10 Minute > 9
  */
  if (StundeWeckzeit < 10 && MinuteWeckzeit < 10) 
  {
    Weckzeit = "0" + String(StundeWeckzeit) + ":0" + String(MinuteWeckzeit);
  }

  if (StundeWeckzeit < 10 && MinuteWeckzeit > 9) 
  {
    Weckzeit = "0" + String(StundeWeckzeit) + ":" + String(MinuteWeckzeit);
  }

  if (StundeWeckzeit > 9 && MinuteWeckzeit < 10) 
  {
    Weckzeit = String(StundeWeckzeit) + ":0" + String(MinuteWeckzeit);
  }

  if (StundeWeckzeit > 9 && MinuteWeckzeit > 9) 
  {
    Weckzeit = String(StundeWeckzeit) + ":" + String(MinuteWeckzeit);
  }
  
  lcd.setCursor(0, 3);
  lcd.print("Weckzeit: " + Weckzeit);

  // führende 0 setzen
  if (aktuell.hour() < 10) Stunde = "0" + String(aktuell.hour());
  else Stunde = String(aktuell.hour());

  // führende 0 setzen
  if (aktuell.minute() < 10) Minute = "0" +  String(aktuell.minute());
  else Minute = String(aktuell.minute());

  // String zusammensetzen
  String aktuelleZeit = Stunde + ":" + Minute;
  if (aktuelleZeit == Weckzeit && aktuell.second() <  DauerWecksignal)
  {
    tone(Lautsprecher, 1000, 500);
  }

  /*
    Ticken der Uhr
    aktuelle Zeit (ZeitJetzt) messen
    millis() -> Zeit, die seit dem Start des Programms
    vergangen ist
    wenn die Differenz zwischen der gerade gemessenen Zeit
    und der im setup gemessenen Startzeit >= 1000 (1 Sekunde) ist
    -> kurzen Ton wiedergeben
    Startzeit muss anschließend auf die aktuelle Zeit gesetzt werden
  */
  ZeitJetzt = millis();
  if (ZeitJetzt - Startzeit >= 1000)
  {
    if (TonSekunde) tone(Lautsprecher, 1000, 2);
    Startzeit = ZeitJetzt;
  }
}