/*
  Arduino | coding-help
  Code help with button
  klapxed - Sunday, February 15, 2026 4:18 PM

  hey everyone, im a beginner and im tryna build a lock with
  a pattern where if i press a button twice, the servo motor
  rotates and opens the lock, however i dont know how to make
  a condition to check whether the button is pressed 2 times
  consecutively, anyone can help?
*/

#include <Servo.h>

const int BTN_PIN = 2;
const int SERVO_PIN = 3;
const unsigned long TIME_OUT = 1000;

bool isLocked = false;
int count = 0;
int oldBtnState = HIGH; // button idles HIGH
unsigned long prevTime = 0;

Servo servo;

bool checkButton()  {
  bool wasPressed = false;

  int btnState = digitalRead(BTN_PIN);  // read the pin
  if (btnState != oldBtnState)  {       // if it changed
    oldBtnState = btnState;             // remember the state
    if (btnState == LOW)  {             // was just pressed
      //Serial.println("Button Pressed");
      wasPressed = true;
    } else  {                           // was just released
      //Serial.println("Button Released");
    }
    delay(20);  // short delay to debounce button
  }
  return wasPressed;
}

void lockServo()  {
  count = 0;
  isLocked = true;
  servo.write(0);
  Serial.println("Locked!");
}

void unlockServo()  {
  count = 0;
  isLocked = false;
  servo.write(180);
  Serial.println("Unlocked!");
}

void setup() {
  Serial.begin(115200);
  pinMode(BTN_PIN, INPUT_PULLUP);
  servo.attach(SERVO_PIN);
  Serial.println("Initializing...");
  lockServo();
}

void loop() {
  bool wasPressed = checkButton();
  // if button was pressed
  if (wasPressed) {
    // if first press set time
    if (count == 0) {
      prevTime = millis();
    }
    // increment count
    count++;
    Serial.println(count);  // for test
    // if count = 1 and not locked, lock it
    if (count == 1) {
      if (!isLocked) {
        lockServo();
      }
    }
    // if count = 2 and inside the time out, unlock, else lock
    if (count == 2) {
      if (millis() - prevTime < TIME_OUT) {
        unlockServo();
      } else  {
        lockServo();
      }
    }
  }
  // see if time has expired, if so reset count
  if (count == 1) {
    if (millis() - prevTime >= TIME_OUT) {
      count = 0;
    }
  }
}