#include <WiFi.h>
#include "PubSubClient.h"
#include <DHT.h>
#include <ESP32Servo.h>

// ----------- WIFI / MQTT -----------
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "test.mosquitto.org";
int port = 1883;

char clientId[50];

WiFiClient espClient;
PubSubClient client(espClient);

// ----------- LEDs (7) -----------
const int ledSala = 23;
const int ledBano = 22;
const int ledCocina = 21;
const int ledExterior = 19;
const int ledGarage = 18;
const int ledHabit1 = 5;
const int ledHabit2 = 17;

// ----------- SERVOS -----------
Servo servoPuerta;
Servo servoPorton;
Servo servoRegadero;

// Pines
const int pinPuerta = 27;
const int pinPorton = 14;
const int pinRegadero = 12;

// Estados
bool puertaAbierta = false;
bool portonAbierto = false;
bool regaderoActivo = false;

// ----------- DHT -----------
#define DHTPIN 16
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

float temperature;
float humidity;

// ----------- CALLBACK MQTT -----------
void callback(char* topic, byte* payload, unsigned int length) {

  String message = "";

  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  Serial.print("Mensaje recibido: ");
  Serial.println(message);

  // ----------- LEDs -----------
  if (message == "Sala ON") digitalWrite(ledSala, HIGH);
  else if (message == "Sala OFF") digitalWrite(ledSala, LOW);

  else if (message == "Bano ON") digitalWrite(ledBano, HIGH);
  else if (message == "Bano OFF") digitalWrite(ledBano, LOW);

  else if (message == "Cocina ON") digitalWrite(ledCocina, HIGH);
  else if (message == "Cocina OFF") digitalWrite(ledCocina, LOW);

  else if (message == "Exterior ON") digitalWrite(ledExterior, HIGH);
  else if (message == "Exterior OFF") digitalWrite(ledExterior, LOW);

  else if (message == "Garage ON") digitalWrite(ledGarage, HIGH);
  else if (message == "Garage OFF") digitalWrite(ledGarage, LOW);

  else if (message == "Habit1 ON") digitalWrite(ledHabit1, HIGH);
  else if (message == "Habit1 OFF") digitalWrite(ledHabit1, LOW);

  else if (message == "Habit2 ON") digitalWrite(ledHabit2, HIGH);
  else if (message == "Habit2 OFF") digitalWrite(ledHabit2, LOW);

  // ----------- PUERTA -----------
  else if (message == "Puerta OPEN") {
    if (!puertaAbierta) {
      servoPuerta.write(90);
      puertaAbierta = true;
    }
  }
  else if (message == "Puerta CLOSED") {
    if (puertaAbierta) {
      servoPuerta.write(0);
      puertaAbierta = false;
    }
  }

  // ----------- PORTÓN -----------
  else if (message == "Porton OPEN") {
    if (!portonAbierto) {
      servoPorton.write(90);
      portonAbierto = true;
    }
  }
  else if (message == "Porton CLOSED") {
    if (portonAbierto) {
      servoPorton.write(0);
      portonAbierto = false;
    }
  }

  // ----------- REGADERO (CONTINUO) -----------
  else if (message == "Regadero ON") {
    if (!regaderoActivo) {
    servoRegadero.write(120); // gira continuo
    regaderoActivo = true;
    }
  }
  else if (message == "Regadero OFF") {
    if (regaderoActivo) {
      servoRegadero.write(90); // STOP real
      regaderoActivo = false;
    }
  }
}

// ----------- WIFI -----------
void wifiConnect() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
}

// ----------- MQTT -----------
void mqttReconnect() {
  while (!client.connected()) {
    Serial.print("Intentando conexión MQTT...");
    long r = random(1000);
    sprintf(clientId, "clientId-%ld", r);

    if (client.connect(clientId)) {
      Serial.println(" conectado");
      client.subscribe("CasaInteligente/Control");
    } else {
      Serial.print("falló, rc=");
      Serial.print(client.state());
      Serial.println(" reintentando...");
      delay(5000);
    }
  }
}

// ----------- SETUP -----------
void setup() {
  Serial.begin(115200);

  wifiConnect();

  Serial.println("WiFi conectado");

  client.setServer(mqttServer, port);
  client.setCallback(callback);

  dht.begin();

  // LEDs
  pinMode(ledSala, OUTPUT);
  pinMode(ledBano, OUTPUT);
  pinMode(ledCocina, OUTPUT);
  pinMode(ledExterior, OUTPUT);
  pinMode(ledGarage, OUTPUT);
  pinMode(ledHabit1, OUTPUT);
  pinMode(ledHabit2, OUTPUT);

  // Configuración servos (CLAVE)
  servoPuerta.setPeriodHertz(50);
  servoPorton.setPeriodHertz(50);
  servoRegadero.setPeriodHertz(50);

  servoPuerta.attach(pinPuerta, 500, 2400);
  servoPorton.attach(pinPorton, 500, 2400);
  servoRegadero.attach(pinRegadero, 500, 2400);

  // Estado inicial
  servoPuerta.write(0);
  servoPorton.write(0);
  servoRegadero.write(90); // quieto
}

// ----------- LOOP -----------
void loop() {
  if (!client.connected()) {
    mqttReconnect();
  }

  client.loop();

  delay(5000);

  // DHT
  temperature = dht.readTemperature();
  humidity = dht.readHumidity();

  String temperatureString = String(temperature, 2);
  String humidityString = String(humidity, 2);

  client.publish("CasaInteligente/temp", temperatureString.c_str());
  client.publish("CasaInteligente/hum", humidityString.c_str());
}