#include <WiFi.h>
#include <HTTPClient.h>
#include <DHT.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define DHTPIN 15
#define DHTTYPE DHT22
#define LED_PIN 2

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

DHT dht(DHTPIN, DHTTYPE);
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

const char* ssid = "Wokwi-GUEST";
const char* password = "";

String apiKey = "A787VDSMNHVR15DZ";
const char* server = "http://api.thingspeak.com/update";

void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi Connected");

  dht.begin();

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println("OLED gagal");
    while (true);
  }

  display.clearDisplay();
}

void loop() {
  float suhu = dht.readTemperature();
  float hum = dht.readHumidity();

  if (isnan(suhu) || isnan(hum)) {
    Serial.println("Gagal baca DHT");
    return;
  }

  // ===== LED CONTROL =====
  if (suhu > 30) {
    digitalWrite(LED_PIN, HIGH);
  } else {
    digitalWrite(LED_PIN, LOW);
  }

  // ===== OLED =====
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 10);
  display.print("Suhu : ");
  display.print(suhu);
  display.println(" C");

  display.setCursor(0, 30);
  display.print("Hum  : ");
  display.print(hum);
  display.println(" %");

  display.display();

  // ===== ThingSpeak =====
  if (WiFi.status() == WL_CONNECTED) {
    HTTPClient http;
    String url = server + String("?api_key=") + apiKey +
                 "&field1=" + String(suhu) +
                 "&field2=" + String(hum);

    http.begin(url);
    int httpCode = http.GET();
    Serial.println("HTTP Code: " + String(httpCode));
    http.end();
  }

  delay(15000); // WAJIB ThingSpeak
}