// Nayla Januarisa Prihadi - J0404241149

#include <WiFi.h>
#include <HTTPClient.h>
#include "DHTesp.h"
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// =====================
// OLED SETUP
// =====================
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// =====================
// WIFI
// =====================
const char* ssid     = "Wokwi-GUEST";
const char* password = "";

// =====================
// THINGSPEAK
// =====================
String writeApiKey = "770ZS1O8JYHNM1UR";
String serverUrl   = "https://api.thingspeak.com/update";

// =====================
// PIN
// =====================
#define DHT_PIN 15
#define LED_PIN 2

DHTesp dht;

// Interval aman Wokwi
unsigned long lastSend = 0;
const unsigned long SEND_INTERVAL_MS = 30000;

void setup() {
  Serial.begin(115200);

  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);

  dht.setup(DHT_PIN, DHTesp::DHT22);

  // OLED init
  Wire.begin(21, 22);
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.clearDisplay();

  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0,0);
  display.println("ESP32 DHT22");
  display.println("Connecting WiFi");
  display.display();

  // WiFi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(300);
  }

  display.println("WiFi OK");
  display.display();
}

void loop() {
  if (millis() - lastSend < SEND_INTERVAL_MS) return;
  lastSend = millis();

  TempAndHumidity data = dht.getTempAndHumidity();

  if (isnan(data.temperature) || isnan(data.humidity)) {
    display.clearDisplay();
    display.setCursor(0,0);
    display.println("DHT ERROR");
    display.display();
    return;
  }

  // URL ThingSpeak
  String url = serverUrl +
               "?api_key=" + writeApiKey +
               "&field1=" + String(data.temperature, 2) +
               "&field2=" + String(data.humidity, 2);

  HTTPClient http;
  http.begin(url);
  int code = http.GET();
  String payload = http.getString();
  http.end();

  bool success = payload.toInt() > 0;

  if (success) {
    digitalWrite(LED_PIN, HIGH);
    delay(200);
    digitalWrite(LED_PIN, LOW);
  }

  // OLED tampilkan status
  display.clearDisplay();
  display.setCursor(0,0);
  display.printf("Temp : %.2f C\n", data.temperature);
  display.printf("Hum  : %.2f %%\n", data.humidity);
  display.println("WiFi : OK");
  display.print("Send : ");
  display.println(success ? "SUCCESS" : "FAILED");
  display.display();
}