// 物聯網時鐘-七段顯示器(六位數)
#include <WiFi.h>
// 網路設定
const char* ssid     = "ESP32";      // Nokia 5.4
const char* password = "12345678";       // 12345678

// 取得網路時間相關參數設定
const char* ntpServer = "time.google.com";  // Google - NTP Server
const long  gmtOffset_sec = 28800;          //台灣時區+8hr,28800=8*60*60
const int   daylightOffset_sec = 0;         //台灣無日光節約時間

// 七段顯示器腳位設定
#define pin_DIG1 14
#define pin_DIG2 23
#define pin_DIG3 22
#define pin_DIG4 19
#define pin_DIG5 27
#define pin_DIG6 26
#define pin_A 12
#define pin_B 21
#define pin_C 5
#define pin_D 2
#define pin_E 15
#define pin_F 13
#define pin_G 18
#define pin_DP 4

// 共陰極、共陽極設定
#define hardwareConfig 0  //COMMON_ANODE=1 COMMON_CATHODE=0
// 條件編譯
#if hardwareConfig==0
// 共陰極
#define digitOn 0
#define digitOff 1
#define light 1
#define dark 0
#else
// 共陽極
#define digitOn 1
#define digitOff 0
#define light 0
#define dark 1
#endif

byte digitPins[6] = {pin_DIG1, pin_DIG2, pin_DIG3, pin_DIG4, pin_DIG5, pin_DIG6};
byte segmentPins[8] = {pin_A, pin_B, pin_C, pin_D, pin_E, pin_F, pin_G, pin_DP};
int num[10][8] = {
  {light, light, light, light, light, light, dark, dark},
  {dark, light, light, dark, dark, dark, dark, dark},
  {light, light, dark, light, light, dark, light, dark},
  {light, light, light, light, dark, dark, light, dark},
  {dark, light, light, dark, dark, light, light, dark},
  {light, dark, light, light, dark, light, light, dark},
  {light, dark, light, light, light, light, light, dark},
  {light, light, light, dark, dark, light, dark, dark},
  {light, light, light, light, light, light, light, dark},
  {light, light, light, light, dark, light, light, dark},                 
};

// 七段顯示器顯示數字
// 顯示1位數字
void displayNum(int pos, int number){
  // 關閉共用腳位
  for(int i = 0; i < 6; i++){
    digitalWrite(digitPins[i], digitOff);
  }
  // 設置數字訊號  
  for(int i = 0; i < 8; i++){
    digitalWrite(segmentPins[i], num[number][i]);
  }
  // 打入數字訊號
  digitalWrite(digitPins[pos], digitOn);
}
// 掃描時間
double scanTime = 1.0/(60*6) * 1000;         // 視覺暫留時間平均約 1/16 秒
// 顯示6位數字
void display(int num0, int num1, int num2, int num3, int num4, int num5, int ms=10){
  for(int i=0; i< ms/(scanTime*6); i++){
    displayNum(0, num0); delay(scanTime);
    displayNum(1, num1); delay(scanTime);
    displayNum(2, num2); delay(scanTime);
    displayNum(3, num3); delay(scanTime);
    displayNum(4, num4); delay(scanTime);
    displayNum(5, num5); delay(scanTime);
  }
}

void setup() {
  // 七段顯示器初始化
  for(int i = 0; i < 6; i++){
    pinMode(digitPins[i], OUTPUT);
    digitalWrite(digitPins[i], digitOff);
  }
  for(int i = 0; i < 8; i++){
    pinMode(segmentPins[i], OUTPUT);
    digitalWrite(segmentPins[i], dark);
  }
  //Serial.begin(115200);
  // Connect to Wi-Fi
  //Serial.print("Connecting to ");
  //Serial.println(ssid);
  //WiFi.begin(ssid, password);             // 以STA(網路終端)模式連接到WiFi基地台
  WiFi.begin("Wokwi-GUEST", "", 6);         // wokwi提供的虛擬 WiFi 接入點
  while (WiFi.status() != WL_CONNECTED) {
    display(8,8,8,8,8,8,200);
    //delay(200);
    //Serial.print(".");
  }
  //Serial.println("");
  //Serial.println("WiFi connected.");
  //Serial.print("IP位址: ");
  //Serial.println(WiFi.localIP());   // 回傳分配到的IP位址
  //Serial.print("WiFi RSSI: ");
  //Serial.println(WiFi.RSSI());      // 回傳接收訊號強度（以 dBm 為單位）

  // Init and get the time
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  //printLocalTime();     // 自定輸出時間函式
}

void loop() {
  printLocalTime();
}

void printLocalTime(){
  struct tm timeinfo;
  if(!getLocalTime(&timeinfo)){
    //Serial.println("Failed to obtain time");
    return;
  }
  //Serial.print("Hour: ");               //顯示 時(24小時制)
  //Serial.println(timeinfo.tm_hour); 
  //Serial.print("Minute: ");             //顯示 分
  //Serial.println(timeinfo.tm_min); 
  //Serial.print("Second: ");             //顯示 秒
  //Serial.println(timeinfo.tm_sec); 
  int num0 = timeinfo.tm_hour / 10;
  int num1 = timeinfo.tm_hour % 10;
  int num2 = timeinfo.tm_min / 10;
  int num3 = timeinfo.tm_min % 10;
  int num4 = timeinfo.tm_sec / 10;
  int num5 = timeinfo.tm_sec % 10;
  display(num0, num1, num2, num3, num4, num5, 200);
  //Serial.println("*****************************************************");
}