#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>
#include <Servo.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// LCD
LiquidCrystal_I2C lcd(0x27, 16, 2);

// OLED
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

// Servo
Servo myServo;

// Buzzer
int buzzer = 11;

// Password
String password = "9353";
String input = "";

// Keypad setup
const byte ROWS = 4;
const byte COLS = 4;

char keys[ROWS][COLS] = {
  {'1','2','3','A'},
  {'4','5','6','B'},
  {'7','8','9','C'},
  {'*','0','#','D'}
};

byte rowPins[ROWS] = {2,3,4,5};
byte colPins[COLS] = {6,7,8,9};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

void setup() {
  lcd.init();
  lcd.backlight();

  pinMode(buzzer, OUTPUT);

  myServo.attach(10);
  myServo.write(0); // Locked position

  // OLED init
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    while(true);
  }

  display.clearDisplay();
  display.setTextSize(2);
  display.setTextColor(WHITE);

  lcd.setCursor(0,0);
  lcd.print("Enter Password");
}

void loop() {
  char key = keypad.getKey();

  if (key) {
    if (key == '#') {
      checkPassword();
      input = "";
    }
    else if (key == '*') {
      input = "";
      display.clearDisplay();
    }
    else {
      input += key;
      showOnOLED();
    }
  }
}

// Display input on OLED
void showOnOLED() {
  display.clearDisplay();
  display.setCursor(0, 20);
  display.print(input);
  display.display();
}

// Check password
void checkPassword() {
  if (input == password) {
    // Correct
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Access Granted");

    display.clearDisplay();
    display.setCursor(0,20);
    display.print("WELCOME");
    display.display();

    myServo.write(90); // Open
    delay(10000);
    myServo.write(0);  // Close

    noTone(buzzer);
  }
  else {
    // Wrong
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Access Denied");

    display.clearDisplay();
    display.setCursor(0,20);
    display.print("WRONG!");
    display.display();

    // Buzzer alert
    tone(buzzer, 1000);
    delay(2000);
    noTone(buzzer);
  }

  delay(2000);
  lcd.clear();
  lcd.print("Enter Password");
}