#include <Wire.h>
#include <Adafruit_BMP085.h>
#include <DHT.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

Adafruit_BMP085 bmp;

#define DHTPIN 2
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

#define EEPROM_ADDR 0x50
int eepromIndex = 0;

void eepromWrite(int addr, byte data) {
  Wire.beginTransmission(EEPROM_ADDR);
  Wire.write(addr >> 8);
  Wire.write(addr & 0xFF);
  Wire.write(data);
  Wire.endTransmission();
  delay(5);
}

byte eepromRead(int addr) {
  Wire.beginTransmission(EEPROM_ADDR);
  Wire.write(addr >> 8);
  Wire.write(addr & 0xFF);
  Wire.endTransmission();

  Wire.requestFrom(EEPROM_ADDR, 1);
  return Wire.read();
}

void setup() {
  Serial.begin(9600);
  Wire.begin();

  if (!bmp.begin()) {
    Serial.println("BMP180 topilmadi!");
    while (1);
  }

  dht.begin();

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println("OLED topilmadi!");
    while (1);
  }

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temp = bmp.readTemperature();
  float pressure = bmp.readPressure() / 100.0;
  float humidity = dht.readHumidity();

  Serial.print("T=");
  Serial.print(temp);
  Serial.print("C P=");
  Serial.print(pressure);
  Serial.print("Pa H=");
  Serial.println(humidity);

  display.clearDisplay();

  display.setCursor(0,0);
  display.print("Har: ");
  display.print(temp);
  display.println(" C");

  display.setCursor(0,20);
  display.print("Bosim: ");
  display.print(pressure);
  display.println(" Pa");

  display.setCursor(0,40);
  display.print("Nam: ");
  display.print(humidity);
  display.println(" %");

  display.display();

  eepromWrite(eepromIndex++, (byte)temp);
  eepromWrite(eepromIndex++, (byte)humidity);

  if (eepromIndex > 100) eepromIndex = 0;

  delay(5000);
}