#include <WiFi.h>
#include <PubSubClient.h>
#include <Keypad.h>

// ---------------- WIFI ----------------
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// ---------------- MQTT (EMQX) ----------------
const char* mqttServer = "broker.emqx.io";
int port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

char clientId[50];

// ---------------- PINS ----------------
#define PIR_PIN 13
#define TRIG_PIN 12
#define ECHO_PIN 14

// ---------------- KEYPAD ----------------
const byte ROWS = 4;
const byte COLS = 4;

char keys[ROWS][COLS] = {
  {'1','2','3','A'},
  {'4','5','6','B'},
  {'7','8','9','C'},
  {'*','0','#','D'}
};

byte rowPins[ROWS] = {19, 18, 5, 17};
byte colPins[COLS] = {16, 4, 0, 2};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

// ---------------- VARIABLES ----------------
String inputCode = "";
String correctCode = "2324";

// ---------------- FUNCTIONS ----------------
long getDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);

  long duration = pulseIn(ECHO_PIN, HIGH);
  return duration * 0.034 / 2;
}

// WIFI INIT
void initWiFi(void) {
  delay(10);
  Serial.println("------ WIFI ------");
  Serial.print("Connecting to: ");
  Serial.println(ssid);

  reconnectWiFi();
}

// MQTT INIT
void initMQTT(void) {
  client.setServer(mqttServer, port);
}

// RECONNECT WIFI
void reconnectWiFi(void) {
  if (WiFi.status() == WL_CONNECTED)
    return;

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(300);
    Serial.print(".");
  }

  Serial.println("\nWiFi Connected!");
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());
}

// RECONNECT MQTT
void reconnectMQTT() {
  while (!client.connected()) {
    Serial.print("Connecting MQTT...");

    long r = random(1000);
    sprintf(clientId, "ESP32-%ld", r);

    if (client.connect(clientId)) {
      Serial.println("Connected!");
    } else {
      Serial.print("Failed rc=");
      Serial.print(client.state());
      Serial.println(" retrying...");
      delay(5000);
    }
  }
}

// CHECK CONNECTIONS
void checkWiFIAndMQTT(void) {
  reconnectWiFi();

  if (!client.connected()) {
    reconnectMQTT();
  }
}

// ---------------- SETUP ----------------
void setup() {
  Serial.begin(115200);

  pinMode(PIR_PIN, INPUT);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);

  initWiFi();
  initMQTT();
}

// ---------------- LOOP ----------------
void loop() {
  checkWiFIAndMQTT();
  client.loop();

  int motion = digitalRead(PIR_PIN);

  if (motion == HIGH) {
    long distance = getDistance();

    Serial.println("Motion detected");
    Serial.print("Distance: ");
    Serial.println(distance);

    // Send distance
    client.publish("intrusion/distance", String(distance).c_str());

    if (distance < 200) {
      Serial.println("Enter Code:");

      inputCode = "";

      while (inputCode.length() < 4) {
        char key = keypad.getKey();
        if (key) {
          inputCode += key;
          Serial.print("*");
        }
      }

      if (inputCode == correctCode) {
        client.publish("intrusion/result", "AUTHORIZED");
        Serial.println("\nAUTHORIZED");
      } else {
        client.publish("intrusion/result", "INTRUS");
        Serial.println("\nINTRUS");
      }
    }
  }

  delay(2000);
}