#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <ArduinoJson.h>

#define DHTPIN 4
#define DHTTYPE DHT22
#define LDR 34
#define LAMP 27
#define AC 26

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.hivemq.com";

WiFiClient espClient;
PubSubClient client(espClient);
DHT dht(DHTPIN, DHTTYPE);

unsigned long lastMsg = 0;
bool lampState = false;
String mode = "auto";

// ================= CALLBACK =================
void callback(char* topic, byte* payload, unsigned int length) {
  String msg;
  for (int i = 0; i < length; i++) msg += (char)payload[i];

  Serial.print("Pesan masuk: ");
  Serial.println(msg);

  // Parsing JSON
  JsonDocument doc;
  DeserializationError error = deserializeJson(doc, msg);

  if (error) {
    Serial.println("JSON Error");
    return;
  }

  // Kontrol lampu
  if (doc["lamp"] == "on") {
    digitalWrite(LAMP, HIGH);
    lampState = true;
  } 
  else if (doc["lamp"] == "off") {
    digitalWrite(LAMP, LOW);
    lampState = false;
  }

  // Kontrol mode
  if (doc["mode"] == "auto") mode = "auto";
  if (doc["mode"] == "manual") mode = "manual";
}

// ================= WIFI =================
void setup_wifi() {
  delay(10);
  Serial.println("Connecting WiFi...");
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi Connected");
}

// ================= RECONNECT MQTT =================
void reconnect() {
  while (!client.connected()) {
    Serial.print("Connecting MQTT...");
    
    if (client.connect("ESP32Client")) {
      Serial.println("Connected");
      client.subscribe("iot/213020503020/control");
    } else {
      Serial.print("Failed, rc=");
      Serial.print(client.state());
      delay(2000);
    }
  }
}

// ================= SETUP =================
void setup() {
  Serial.begin(115200);

  setup_wifi();

  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  pinMode(LAMP, OUTPUT);
  pinMode(AC, OUTPUT);

  dht.begin();
}

// ================= LOOP =================
void loop() {
  if (!client.connected()) reconnect();
  client.loop();

  unsigned long now = millis();

  if (now - lastMsg > 5000) {
    lastMsg = now;

    float t = dht.readTemperature();
    float h = dht.readHumidity();
    int light = analogRead(LDR);

    // MODE AUTO
    if (mode == "auto") {
      digitalWrite(AC, t > 28);
      digitalWrite(LAMP, light < 400);
    }

    // JSON KIRIM DATA
    JsonDocument doc;
    doc["temp"] = t;
    doc["hum"] = h;
    doc["light"] = light;
    doc["mode"] = mode;
    doc["lamp"] = lampState;

    char buffer[256];
    serializeJson(doc, buffer);

    client.publish("iot/213020503020/data", buffer, true);

    Serial.println(buffer);
  }
}