#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHTesp.h>

#define DHTPIN     4
#define OLED_SDA   21
#define OLED_SCL   22

#define LED_OK     32
#define LED_LOW    19
#define LED_HIGH   25

#define FAN_PIN    33
#define RELAY_PIN  13

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_ADDR 0x3C

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);
DHTesp dhtSensor;

const float TEMP_LOW  = 36.0;
const float TEMP_HIGH = 37.5;

const float FAN_ON_TEMP  = 37.6;
const float FAN_OFF_TEMP = 37.2;

#define RELAY_ON_STATE  LOW
#define RELAY_OFF_STATE HIGH

float temperature = NAN;
float humidity = NAN;

bool fanState = false;
bool heaterState = false;

void setLEDs(bool okLed, bool lowLed, bool highLed) {
  digitalWrite(LED_OK, okLed ? HIGH : LOW);
  digitalWrite(LED_LOW, lowLed ? HIGH : LOW);
  digitalWrite(LED_HIGH, highLed ? HIGH : LOW);
}

void heaterOn() {
  heaterState = true;
  digitalWrite(RELAY_PIN, RELAY_ON_STATE);
}

void heaterOff() {
  heaterState = false;
  digitalWrite(RELAY_PIN, RELAY_OFF_STATE);
}

const char* estadoTermico(float t) {
  if (isnan(t)) return "ERROR";
  if (t < TEMP_LOW) return "BAJA";
  if (t > TEMP_HIGH) return "ALTA";
  return "OK";
}

void leerDHT() {
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  if (!isnan(data.temperature)) temperature = data.temperature;
  if (!isnan(data.humidity)) humidity = data.humidity;
}

void actualizarLEDs(float t) {
  if (isnan(t)) {
    setLEDs(false, false, false);
  } else if (t < TEMP_LOW) {
    setLEDs(false, true, false);
  } else if (t > TEMP_HIGH) {
    setLEDs(false, false, true);
  } else {
    setLEDs(true, false, false);
  }
}

void actualizarVentilador(float t) {
  if (isnan(t)) {
    fanState = false;
  } else {
    if (t >= FAN_ON_TEMP) fanState = true;
    else if (t <= FAN_OFF_TEMP) fanState = false;
  }
  digitalWrite(FAN_PIN, fanState ? HIGH : LOW);
}

void actualizarBombillo(float t) {
  if (isnan(t)) {
    heaterOff();
    return;
  }

  if (t <= 36.0) {
    heaterOn();
  } else if (t >= 37.5) {
    heaterOff();
  }
}

void mostrarOLED() {
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);

  display.println("Simulacion temp");
  display.println("----------------");

  display.print("T: ");
  display.print(temperature, 1);
  display.println(" C");

  display.print("H: ");
  display.print(humidity, 0);
  display.println(" %");

  display.print("Estado: ");
  display.println(estadoTermico(temperature));

  display.print("Heat: ");
  display.print(heaterState ? "ON " : "OFF");

  display.print(" Fan: ");
  display.println(fanState ? "ON" : "OFF");

  display.display();
}

void setup() {
  Serial.begin(115200);

  pinMode(LED_OK, OUTPUT);
  pinMode(LED_LOW, OUTPUT);
  pinMode(LED_HIGH, OUTPUT);

  pinMode(FAN_PIN, OUTPUT);
  digitalWrite(FAN_PIN, LOW);

  pinMode(RELAY_PIN, OUTPUT);
  heaterOff();

  Wire.begin(OLED_SDA, OLED_SCL);
  display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR);

  dhtSensor.setup(DHTPIN, DHTesp::DHT22);
}

void loop() {
  leerDHT();
  actualizarLEDs(temperature);
  actualizarBombillo(temperature);
  actualizarVentilador(temperature);
  mostrarOLED();
  delay(800);
}