#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

const char* ssid = "Wokwi-GUEST";
const char* pwd = "";
const char* broker = "broker.hivemq.com";
const char* t_led = "IOT-G9/led";
const char* t_temp = "IOT-G9/temp";
const char* t_hum = "IOT-G9/hum";

const int dhtPin = 4; 
const int ledPin = 2;

DHT dht(dhtPin, DHT22);
WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;

void callback(char* t, byte* payload, unsigned int len) {
  String msg = String((char*)payload, len);
  if (msg == "on") digitalWrite(ledPin, HIGH);
  if (msg == "off") digitalWrite(ledPin, LOW);
}

void setup() {
  pinMode(ledPin, OUTPUT);
  dht.begin();
  
  WiFi.begin(ssid, pwd);
  while (WiFi.status() != WL_CONNECTED) delay(50);
  
  client.setServer(broker, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    if (client.connect("ESP32_Wokwi")) {
      client.subscribe(t_led);
    }
    delay(500);
  } else {
    client.loop();
    unsigned long now = millis();
    if (now - lastMsg > 5000) {
      lastMsg = now;
      client.publish(t_temp, String(dht.readTemperature()).c_str());
      client.publish(t_hum, String(dht.readHumidity()).c_str());
    }
  }
}