#include <Servo.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

#define SERVO_PIN 9
#define DHT_PIN A1
#define DHT_TYPE DHT22
#define LDR_PIN A0

#define WINDOW_CLOSED 0
#define WINDOW_VENT 45
#define WINDOW_OPEN 90

#define TEMP_HIGH 30.0
#define TEMP_LOW 20.0
#define LIGHT_THRESHOLD 500

Adafruit_SSD1306 display(128, 64, &Wire, -1);
Servo windowServo;
DHT dht(DHT_PIN, DHT_TYPE);

int currentAngle = 0;
int lightValue = 0;
float tempValue = 0;

void moveServo(int targetAngle, int speed)
{
  int step = targetAngle > currentAngle ? 1 : -1;
  while (currentAngle != targetAngle)
  {
    currentAngle += step;
    windowServo.write(currentAngle);
    delay(speed);
    updateDisplay();
  }
}

void closeWindow()
{
  moveServo(WINDOW_CLOSED, 10);
}

void ventWindow()
{
  moveServo(WINDOW_VENT, 15);
}

void openWindow()
{
  moveServo(WINDOW_OPEN, 15);
}

void updateDisplay()
{
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(10, 2);
  display.print("Smart Window");
  display.drawLine(0, 12, 128, 12, WHITE);

  display.setCursor(10, 20);
  display.print("Temp: ");
  display.print(tempValue, 1);
  display.print(" C");

  display.setCursor(10, 32);
  display.print("Light: ");
  display.print(lightValue);

  display.setCursor(10, 44);
  display.print("Angle: ");
  display.print(currentAngle);
  display.display();
}

void readSensors()
{
  lightValue = analogRead(LDR_PIN);
  tempValue = dht.readTemperature();
  if (isnan(tempValue)) tempValue = 25;
}

void setup()
{
  Serial.begin(9600);
  windowServo.attach(SERVO_PIN);
  dht.begin();
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  windowServo.write(WINDOW_CLOSED);
  currentAngle = WINDOW_CLOSED;
  delay(1000);
}

void loop()
{
  readSensors();

  // 光照大于500才执行温控动作，小于则保持不动
  if (lightValue > LIGHT_THRESHOLD)
  {
    if (tempValue > TEMP_HIGH)
    {
      openWindow();
    }
    else if (tempValue < TEMP_LOW)
    {
      closeWindow();
    }
    else
    {
      ventWindow();
    }
  }

  updateDisplay();
  delay(500);
}