#include <Arduino.h>
#ifdef ESP8266 
 #include <ESP8266WiFi.h>
#endif 
#ifdef ESP32   
 #include <WiFi.h>
#endif
 
// Adiciona as bibliotecas para conexão com o Sinric
#include "SinricPro.h"
#include "SinricProSwitch.h"
 
// Dados de conexão WiFi
#define WIFI_SSID         "Wokwi-GUEST"
#define WIFI_PASS         ""
 
// Dados de conexão ao Sinric
#define APP_KEY           "Adicione aqui a Chave do App"
#define APP_SECRET        "Adicione aqui a Senha do App"
 
// Velocidade de comunicação Serial
#define BAUD_RATE         115200
 
// Pinos dos LEDs
#define RELAYPIN_1        32 // LED Vermelho
#define RELAYPIN_2        33 // LED Verde
 
// Configura LED/Pinos para o Sinric
struct RelayInfo {
  String deviceId;
  String name;
  int pin;
};
 
std::vector<RelayInfo> relays = {
    {"adicione aqui o ID do LED", "LED Vermelho", RELAYPIN_1},
    {"adicione aqui o ID do LED", "LED Verde"   , RELAYPIN_2}};
/*   ^^^^^^^^^^^^^^^^^^^^^^^^^   ^^^^^^^^^         ^^^
 *              |                     |            |
 *              |                     |            +----> Pino
 *              |                     +-----------------> Nome que será impresso no terminal serial
 *              +---------------------------------------> ID do dispositivo
*/
 
// Função que comanda os LEDs -> Ligar e Desligar via Sinric
bool onPowerState(const String &deviceId, bool &state) {
 
  // Percorre todos os dispositivos configurados antes.
  for (auto &relay : relays) {                                                            
    if (deviceId == relay.deviceId) {                                                     
      Serial.printf("Dispositivo %s está %s\r\n", relay.name.c_str(), state ? "ligado" : "desligado");
      digitalWrite(relay.pin, state);                                                         
      return true;                                                                            
    }
  }
  return false; // if no relay configuration was found, return false
}
 
// Conecta ao WiFi
void setupWiFi() 
{
  Serial.printf("\r\n[Wifi]: Conectando");
  WiFi.begin(WIFI_SSID, WIFI_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    Serial.printf(".");
    delay(250);
  }
  IPAddress localIP = WiFi.localIP();
  Serial.printf("Conectado!\n[WiFi]: Endereço IP: %d.%d.%d.%d\r\n", localIP[0], localIP[1], localIP[2], localIP[3]);
}
 
 
// Configura conexão ao Sinric
void setupSinricPro() 
{  
  // Configura cada dispositivo
  for (auto &relay : relays) {                             
    SinricProSwitch &mySwitch = SinricPro[relay.deviceId]; 
    mySwitch.onPowerState(onPowerState);                   
  }
  Serial.printf("Conectando ao SinricPro\r\n");
 
  // Configura Sinric
  SinricPro.onConnected([]() {
    Serial.printf("Conectado ao SinricPro\r\n");
  });
  SinricPro.onDisconnected([]() {
    Serial.printf("Desconectado do SinricPro\r\n");
  });
 
  // Conecta ao Sinric
  SinricPro.begin(APP_KEY, APP_SECRET);
}
 
 
// Função Setup
void setup() 
{
  Serial.begin(BAUD_RATE);
  pinMode(RELAYPIN_1, OUTPUT);
  pinMode(RELAYPIN_2, OUTPUT);
  setupWiFi();
  setupSinricPro();
}
 
// Função Loop
void loop() 
{
  SinricPro.handle();
}