#include <WiFi.h>
#include <PubSubClient.h>
#include <HTTPClient.h>
#include <ArduinoJson.h>
#include <DHT.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "broker.hivemq.com";

const char* mqtt_topic_weather   = "weather/suburbs";
const char* mqtt_topic_summary   = "weather/summary";
const char* mqtt_topic_pollution = "weather/Pollution";

const char* apiKey = "1e4fad19e905cfb8553e1a004d2153d1";

#define DHTPIN 26
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

float ALERT_THRESHOLD = 3.0;

WiFiClient espClient;
PubSubClient client(espClient);

struct Suburb {
  const char* name;
  const char* query;
  float lat;
  float lon;
};

Suburb suburbs[] = {
  {"Bellville",     "Bellville,ZA",   0,        0      },
  {"Belhar",        "Belhar,ZA",      0,        0      },
  {"Cape Town CBD", NULL,            -33.9249,  18.4241},
  {"Kuilsrivier",   "Kuilsrivier,ZA", 0,        0      }
};
const int suburbCount = 4;

void connectWiFi() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("WiFi Connected");
}

void connectMQTT() {
  if (client.connected()) return;
  Serial.print("Attempting MQTT connection...");
  String clientId = "ESP32Client-" + String(random(0xffff), HEX);
  if (client.connect(clientId.c_str())) {
    Serial.println("Connected to MQTT broker");
  } else {
    Serial.print("Failed, state: ");
    Serial.println(client.state());
  }
}

float fetchWeather(Suburb s) {
  HTTPClient http;
  char url[200];

  if (s.query != NULL) {
    sprintf(url, "https://api.openweathermap.org/data/2.5/weather?q=%s&appid=%s&units=metric", s.query, apiKey);
  } else {
    sprintf(url, "https://api.openweathermap.org/data/2.5/weather?lat=%.4f&lon=%.4f&appid=%s&units=metric", s.lat, s.lon, apiKey);
  }

  http.begin(url);
  int httpCode = http.GET();

  if (httpCode == 200) {
    String response = http.getString();

    StaticJsonDocument<1024> doc;
    deserializeJson(doc, response);

    float p_temp       = doc["main"]["temp"];
    float p_humidity   = doc["main"]["humidity"];
    float p_feelsLike  = doc["main"]["feels_like"];
    float p_windSpeed  = doc["wind"]["speed"];
    const char* p_desc = doc["weather"][0]["description"];
    float p_lat        = doc["coord"]["lat"];
    float p_lon        = doc["coord"]["lon"];

    char payload[512];
    sprintf(payload,
      "{\"suburb\":\"%s\","
      "\"temp\":%.1f,"
      "\"humidity\":%.1f,"
      "\"feels_like\":%.1f,"
      "\"wind_speed\":%.1f,"
      "\"desc\":\"%s\","
      "\"lat\":%.4f,"
      "\"lon\":%.4f}",
      s.name, p_temp, p_humidity, p_feelsLike, p_windSpeed, p_desc, p_lat, p_lon);

    client.publish(mqtt_topic_weather, payload);
    Serial.println(payload);

    http.end();
    delay(2000);
    return p_temp;

  } else {
    Serial.print("Weather HTTP Error for ");
    Serial.print(s.name);
    Serial.print(": ");
    Serial.println(httpCode);
    http.end();
    return -999;
  }
}

void fetchPollution(Suburb s) {
  HTTPClient http;
  char url[200];

  float queryLat, queryLon;
  if      (strcmp(s.name, "Bellville")     == 0) { queryLat = -33.9160; queryLon = 18.6282; }
  else if (strcmp(s.name, "Belhar")        == 0) { queryLat = -33.9167; queryLon = 18.6833; }
  else if (strcmp(s.name, "Cape Town CBD") == 0) { queryLat = -33.9249; queryLon = 18.4241; }
  else                                            { queryLat = -33.9333; queryLon = 18.7167; }
  // fixed — removed the broken else (strcmp...) == 0) ;{ syntax

  sprintf(url, "http://api.openweathermap.org/data/2.5/air_pollution?lat=%.4f&lon=%.4f&appid=%s", queryLat, queryLon, apiKey);

  http.begin(url);
  int httpCode = http.GET();

  if (httpCode == 200) {
    String response = http.getString();

    StaticJsonDocument<1024> doc;
    deserializeJson(doc, response);

    int   p_aqi  = doc["list"][0]["main"]["aqi"];
    float p_co   = doc["list"][0]["components"]["co"];
    float p_no2  = doc["list"][0]["components"]["no2"];
    float p_o3   = doc["list"][0]["components"]["o3"];
    float p_pm25 = doc["list"][0]["components"]["pm2_5"];
    float p_pm10 = doc["list"][0]["components"]["pm10"];

    char payload[512];
    sprintf(payload,
      "{\"suburb\":\"%s\","
      "\"aqi\":%d,"
      "\"co\":%.2f,"
      "\"no2\":%.2f,"
      "\"o3\":%.2f,"
      "\"pm25\":%.2f,"
      "\"pm10\":%.2f,"
      "\"lat\":%.4f,"
      "\"lon\":%.4f}",
      s.name, p_aqi, p_co, p_no2, p_o3, p_pm25, p_pm10, queryLat, queryLon);

    client.publish(mqtt_topic_pollution, payload);
    Serial.println(payload);

  } else {
    Serial.print("Pollution HTTP Error for ");
    Serial.print(s.name);
    Serial.print(": ");
    Serial.println(httpCode);
  }

  http.end();
  delay(1000);
}

void setup() {
  Serial.begin(115200);
  dht.begin();
  delay(2000);
  connectWiFi();
  client.setServer(mqtt_server, 1883);
  connectMQTT();
}

void loop() {
  client.loop();

  if (!client.connected()) {
    connectMQTT();
  }

  float n_totalTemp = 0;
  int n_validCount  = 0;

  for (int i = 0; i < suburbCount; i++) {
    float n_temp = fetchWeather(suburbs[i]);
    if (n_temp != -999) {
      n_totalTemp += n_temp;
      n_validCount++;
    }
  }

  if (n_validCount > 0) {
    float n_avgTemp = n_totalTemp / n_validCount;

    float p_sensorTemp     = dht.readTemperature();
    float p_sensorHumidity = dht.readHumidity();

    if (isnan(p_sensorTemp) || isnan(p_sensorHumidity)) {
      delay(2000);
      p_sensorTemp     = dht.readTemperature();
      p_sensorHumidity = dht.readHumidity();
    }

    if (!isnan(p_sensorTemp) && !isnan(p_sensorHumidity)) {
      float n_deviation = p_sensorTemp - n_avgTemp;
      bool  b_alert     = abs(n_deviation) > ALERT_THRESHOLD;

      char payload[512];
      sprintf(payload,
        "{\"avg_temp\":%.1f,"         // fixed — removed the rogue opening quote
        "\"sensor_temp\":%.1f,"
        "\"sensor_humidity\":%.1f,"
        "\"deviation\":%.1f,"
        "\"alert\":%s}",
        n_avgTemp, p_sensorTemp, p_sensorHumidity, n_deviation, b_alert ? "true" : "false");

      client.publish(mqtt_topic_summary, payload);
      Serial.println(payload);

    } else {
      Serial.println("DHT22 read failed after retry");
    }
  }

  for (int i = 0; i < suburbCount; i++) {
    fetchPollution(suburbs[i]);
  }

  delay(30000);
}