#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// WiFi Settings
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// MQTT Settings
const char* mqtt_server = "broker.hivemq.com";
const char* mqtt_topic = "boikago";

// DHT22 Settings
#define DHTPIN 4
#define DHTTYPE DHT22

DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);

void connectWiFi() {

  Serial.begin(115200);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }

  Serial.println("WiFi Connected");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {

  String message = "";

  for (unsigned int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  Serial.print("Received message: ");
  Serial.println(message);
}

void connectMQTT() {

  while (!client.connected()) {

    Serial.println("Attempting MQTT connection...");

    String clientId = "ESP32Client-" + String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {

      Serial.println("Connected to MQTT broker");

      client.subscribe(mqtt_topic);

    } else {

      Serial.print("Failed, state: ");
      Serial.println(client.state());

      delay(5000);
    }
  }
}

void setup() {

  connectWiFi();

  dht.begin();

  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  connectMQTT();
}

void loop() {

  if (!client.connected()) {
    connectMQTT();
  }

  client.loop();

  float temp = dht.readTemperature();
  float hum = dht.readHumidity();

  String tempStr = String(temp, 2);
  String humStr = String(hum, 2);

  Serial.print("Temperature: ");
  Serial.println(tempStr);

  Serial.print("Humidity: ");
  Serial.println(humStr);

  client.publish("boikago/temperature", tempStr.c_str());
  client.publish("boikago/humidity", humStr.c_str());

  delay(2000);
}