#include <WiFi.h>
#include <PubSubClient.h>

// Configuración WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Configuración MQTT
const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;
const char* pubTopic = "vaas/sensores";
const char* subTopic = "vaas/relay";

WiFiClient espClient;
PubSubClient client(espClient);

// Pines
#define MQ2_PIN 36
#define TRIG_PIN 5
#define ECHO_PIN 18
#define RELAY_PIN 23

long lastMsg = 0;

void callback(char* topic, byte* payload, unsigned int length) {
  String msg;
  for (unsigned int i = 0; i < length; i++) {
    msg += (char)payload[i];
  }
  if (msg == "ON") {
    digitalWrite(RELAY_PIN, HIGH);
    Serial.println("Relay ACTIVADO");
  } else if (msg == "OFF") {
    digitalWrite(RELAY_PIN, LOW);
    Serial.println("Relay DESACTIVADO");
  }
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect("ArduinoClient")) {
      client.subscribe(subTopic);
    } else {
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(RELAY_PIN, OUTPUT);

   WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 10000) {
    lastMsg = now;

    // MQ2 lectura
    int mq2Value = analogRead(MQ2_PIN);

    // HC-SR04 lectura
    digitalWrite(TRIG_PIN, LOW);
    delayMicroseconds(2);
    digitalWrite(TRIG_PIN, HIGH);
    delayMicroseconds(10);
    digitalWrite(TRIG_PIN, LOW);
    long duration = pulseIn(ECHO_PIN, HIGH);
    int distance = duration * 0.034 / 2;

    // Publicar JSON
    String payload = "{\"mq2\":" + String(mq2Value) + ",\"distancia\":" + String(distance) + "}";
    client.publish(pubTopic, payload.c_str());
    Serial.println("Publicado: " + payload);
  }
}